如何暂停一个线程？

Question

我想画一些东西。由于GUI冻结，我想绘制一个线程。但有时我想暂停绘图（几分钟）。

德尔福的文档说暂停/恢复已过时，但不知道哪些功能替代它们。

暂停和恢复已弃用。 Sleep和SpinWait显然不合适。我很惊讶地发现Delphi不提供这样一个基本的属性/特性。

那么，我该如何暂停/恢复一个线程？

Answer 1

您可能需要通过关键部分的fPaused/fEvent保护。这取决于你的具体实现。

interface 

uses 
    Classes, SyncObjs; 

type 
    TMyThread = class(TThread) 
    private 
    fEvent: TEvent; 
    fPaused: Boolean; 
    procedure SetPaused(const Value: Boolean); 
    protected 
    procedure Execute; override; 
    public 
    constructor Create(const aPaused: Boolean = false); 
    destructor Destroy; override; 

    property Paused: Boolean read fPaused write SetPaused; 
    end; 

implementation 

constructor TMyThread.Create(const aPaused: Boolean = false); 
begin 
    fPaused := aPaused; 
    fEvent := TEvent.Create(nil, true, not fPaused, ''); 
    inherited Create(false); 
end; 

destructor TMyThread.Destroy; 
begin 
    Terminate; 
    fEvent.SetEvent; 
    WaitFor; 
    fEvent.Free; 
    inherited; 
end; 

procedure TMyThread.Execute; 
begin 
    while not Terminated do 
    begin 
    fEvent.WaitFor(INFINITE); 
    // todo: your drawings here 
    end; 
end; 

procedure TMyThread.SetPaused(const Value: Boolean); 
begin 
    if (not Terminated) and (fPaused <> Value) then 
    begin 
    fPaused := Value; 
    if fPaused then 
     fEvent.ResetEvent else 
     fEvent.SetEvent; 
    end; 
end;