如何以编程方式冻结Excel 2007 VBA中Excel工作表的首行？

Question

我正在寻找以编程方式从VBA冻结Excel工作表的第一行。最终目标是产生与Excel 2007中的View > Freeze Panes > Freeze Top Row命令相同的效果，以便冻结工作表的第一行，并且即使在滚动数据时用户也可以看到工作表的第一行。

Answer 1

Rows("2:2").Select 
ActiveWindow.FreezePanes = True 

为不同的效果选择不同的范围，这与您手动操作的方式非常相似。 “Freeze Top Row”实际上是Excel 2007（及更高版本）中的一项新增功能，与早期版本的Excel相比，它不包含任何附加功能。

Answer 2

Tomalak已经给了你一个正确的答案，但是我想补充一点，当你想知道在用户界面中做某个动作所需的VBA代码时，最好记录一个宏。

在这种情况下，请在功能区的开发人员选项卡上单击记录宏，冻结最上一行然后停止记录。 Excel将有记录，你下面的宏也不会工作：

With ActiveWindow 
    .SplitColumn = 0 
    .SplitRow = 1 
End With 
ActiveWindow.FreezePanes = True 

Answer 3

与录制宏的问题是相同的，与内置的动作问题：Excel中选择冻顶可见行，而不是可以找到标题信息的实际顶行。

在这种情况下宏的目的是冻结实际的顶行。当我正在查看第405592行时，我需要检查列的标题（因为我在打开文件时忘记冻结行），所以我必须滚动到顶部，冻结第一行，然后找到返回的路再次行＃405592。既然我认为这是愚蠢的行为，我想要一个宏来纠正它，但正如我所说，录制的宏只是模仿了同样愚蠢的行为。

我使用Office 2011的Mac OS X Lion的

更新（2分钟后）：

我发现这里的解决方案：http://www.ozgrid.com/forum/showthread.php?t=19692

Dim r As Range 
Set r = ActiveCell 
Range("A2").Select 
With ActiveWindow 
    .FreezePanes = False 
    .ScrollRow = 1 
    .ScrollColumn = 1 
    .FreezePanes = True 
    .ScrollRow = r.Row 
End With 
r.Select 

Answer 4

只要按同样的问题.. 。 出于某种原因，freezepanes命令只是导致十字线出现在屏幕的中心。它变成了我关掉ScreenUpdating的功能！ 用以下代码解决：

Application.ScreenUpdating = True 
Cells(2, 1).Select 
ActiveWindow.FreezePanes = True 

现在它工作正常。

Answer 5

Rows("2:2").Select 
ActiveWindow.FreezePanes = True 

这是冻结第一行的最简单方法。 FreezePanes的规则是冻结您选择的单元格中的左上角。例如，如果突出显示C10，它将在列B和C之间的第9行和第10行之间冻结。因此，当突出显示第2行时，它实际上会冻结在第1行和第2行之间，即第一行。

而且，.SplitColumn或.SplitRow会在您解冻窗口后拆分窗口，这不是我喜欢的方式。

Answer 6

要将此问题扩展到Excel 自己的VBA之外的使用领域，ActiveWindow property必须作为Excel.Application object的子代来处理。

从Access中创建一个Excel工作簿

例子：

在其他Office应用程序的VBA项目使用Excel.Application object会要求你添加的Microsoft Excel 15.0对象库（或等同于你自己的版本）。

Option Explicit 

Sub xls_Build__Report() 
    Dim xlApp As Excel.Application, ws As Worksheet, wb As Workbook 
    Dim fn As String 

    Set xlApp = CreateObject("Excel.Application") 
    xlApp.DisplayAlerts = False 
    xlApp.Visible = True 

    Set wb = xlApp.Workbooks.Add 
    With wb 
     .Sheets(1).Name = "Report" 
     With .Sheets("Report") 

      'report generation here 

     End With 

     'This is where the Freeze Pane is dealt with 
     'Freezes top row 
     With xlApp.ActiveWindow 
      .SplitColumn = 0 
      .SplitRow = 1 
      .FreezePanes = True 
     End With 

     fn = CurrentProject.Path & "\Reports\Report_" & Format(Date, "yyyymmdd") & ".xlsx" 
     If CBool(Len(Dir(fn, vbNormal))) Then Kill fn 
     .SaveAs FileName:=fn, FileFormat:=xlOpenXMLWorkbook 
    End With 

Close_and_Quit: 
    wb.Close False 
    xlApp.Quit 
End Sub 

制造过程的核心其实就是一个先前提交答案的重申，但我想证明如何处理的ActiveWindow时，你是不是Excel的VBA本身内是很重要的。虽然这里的代码是VBA，但它应该可以直接转录到其他语言和平台。