如何搜索匹配字符串的Perl数组？

Question

什么是在Perl中搜索匹配字符串的最简单的方法？

一个警告，我想搜索不区分大小写

所以"aAa"将是("aaa","bbb")

Answer 1

我猜

@foo = ("aAa", "bbb"); 
@bar = grep(/^aaa/i, @foo); 
print join ",",@bar; 

会做的伎俩。

Answer 2

#!/usr/bin/env perl 

use strict; 
use warnings; 
use Data::Dumper; 

my @bar = qw(aaa bbb); 
my @foo = grep {/aAa/i} @bar; 

print Dumper \@foo; 

Answer 3

这取决于你想要搜索的事：

• ，如果你想找到所有匹配，使用内置grep：

  my @matches = grep { /pattern/ } @list_of_strings; 
  

• 如果你想

  找到第一次匹配，使用first in List::Util：

  use List::Util 'first'; 
  my $match = first { /pattern/ } @list_of_strings; 
  

• ，如果你想找到的所有比赛的计数，使用true在List::MoreUtils：

  use List::MoreUtils 'true'; 
  my $count = true { /pattern/ } @list_of_strings; 
  

• ，如果你想知道指数的第一场比赛的，在List::MoreUtils使用first_index ：

  use List::MoreUtils 'first_index'; 
  my $index = first_index { /pattern/ } @list_of_strings; 
  

• 如果你想简单地k现在如果有一个匹配，但你不在乎哪个元素它或它的价值，使用any在List::Util：

  use List::Util 1.33 'any'; 
  my $match_found = any { /pattern/ } @list_of_strings; 
  

所有这些例子在他们的核心做类似的事情，但他们的这些实现经过了大量优化，速度很快，并且比使用grep,map或for loop编写的纯perl实现要快。

---

请注意，执行循环的算法是一个单独的问题，而不是执行单个匹配。要不区分大小写地匹配一个字符串，您可以简单地使用i标志的模式：/pattern/i。如果您之前没有这样做，您一定要通读perldoc perlre。

Answer 4

如果你会做许多搜索数组，和匹配总是被定义为等价的字符串，那么你就可以标准化您的数据和使用散列。

my @strings = qw(aAa Bbb cCC DDD eee); 

my %string_lut; 

# Init via slice: 
@string_lut{ map uc, @strings } =(); 

# or use a for loop: 
# for my $string (@strings) { 
#  $string_lut{ uc($string) } = undef; 
# } 


#Look for a string: 

my $search = 'AAa'; 

print "'$string' ", 
    (exists $string_lut{ uc $string ? "IS" : "is NOT"), 
    " in the array\n"; 

让我强调一下，如果您计划在数组上进行多次查找，那么做一个哈希查找是很好的。此外，只有在匹配意味着$foo eq $bar或通过规范化才能满足其他要求（如不区分大小写）的情况下，它才会起作用。

Answer 5

的Perl 5.10+包含“智能匹配”操作符~~，如果某个元素包含在一个数组或哈希返回true，假如果不（见perlfaq4）：

的好处事情是，它也支持正则表达式，这意味着你不区分大小写的要求可以很容易地照顾：

use strict; 
use warnings; 
use 5.010; 

my @array = qw/aaa bbb/; 
my $wanted = 'aAa'; 

say "'$wanted' matches!" if /$wanted/i ~~ @array; # Prints "'aAa' matches!" 

Answer 6

Perl的字符串匹配，也可用于简单的是/否。

my @foo=("hello", "world", "foo", "bar"); 

if ("@foo" =~ /\bhello\b/){ 
    print "found"; 
} 
else{ 
    print "not found"; 
} 

Answer 7

对于刚刚一个布尔匹配结果或发生计数，你可以使用：

use 5.014; use strict; use warnings; 
my @foo=('hello', 'world', 'foo', 'bar', 'hello world', 'HeLlo'); 
my $patterns=join(',',@foo); 
for my $str (qw(quux world hello hEllO)) { 
    my $count=map {m/^$str$/i} @foo; 
    if ($count) { 
     print "I found '$str' $count time(s) in '$patterns'\n"; 
    } else { 
     print "I could not find '$str' in the pattern list\n" 
    }; 
} 

输出：

I could not find 'quux' in the pattern list 
I found 'world' 1 time(s) in 'hello,world,foo,bar,hello world,HeLlo' 
I found 'hello' 2 time(s) in 'hello,world,foo,bar,hello world,HeLlo' 
I found 'hEllO' 2 time(s) in 'hello,world,foo,bar,hello world,HeLlo' 

不要求使用的模块。
当然，它不像上面的代码那样“可扩展”和多功能。
我使用这个交互式用户答案来匹配预定义的一组不区分大小写的答案。