xsl：apply-templates不会遍历选择的每个节点

我正在使用Saxon HE 9-4-0-3J。我的意图是使用xsl:apply-templates上的select属性遍历每个<RECORD>元素，但xml中只有一个<RECORD>元素正在处理中。xsl：apply-templates不会遍历选择的每个节点

XML

<ENVELOPE> 
<PRODUCT> 
    <HEAD><FLAG>No</FLAG></HEAD> 
    <BODY> 
     <RECORD><Value>9</Value></RECORD> 
     <RECORD><Value>10</Value></RECORD> 
     <MISC>9</MISC> 
    </BODY> 
</PRODUCT>

XSLT 2.0

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

<xsl:template match="/ENVELOPE"> 
<Interface> 
    <Data><xsl:apply-templates select="PRODUCT"/></Data> 
</Interface> 
</xsl:template> 

<xsl:template match="PRODUCT"> 
    <xsl:choose> 
     <xsl:when test="HEAD/FLAG='Yes'"> 
     <xsl:attribute name="Match">Affirmative</xsl:attribute> 
     <xsl:apply-templates select="BODY/RECORD" mode="affr"/> 
     </xsl:when> 
     <xsl:when test="HEAD/FLAG='No'"> 
     <xsl:attribute name="Match">Negative</xsl:attribute> 
     <xsl:apply-templates select="BODY/RECORD" mode="neg"/> 
     </xsl:when> 
    </xsl:choose> 
</xsl:template> 

<xsl:template match="RECORD" mode="affr"> 
    <xsl:attribute name="Value"><xsl:value-of select="Value"/></xsl:attribute> 
</xsl:template> 

<xsl:template match="RECORD" mode="neg"> 
    <xsl:attribute name="Value"><xsl:value-of select="Value"/></xsl:attribute> 
</xsl:template> 

</xsl:stylesheet>

输出

<Interface> 
     <Data Match="Negative" Value="9"/> <!-- this line doesn't appear, I want it to --> 
     <Data Match="Negative" Value="10"/> 
</Interface>

来源

2012-04-14 satish b

当您匹配<ENVELOPE...>时会生成<DATA...>输出标签，因此只能有其中一个输出。任何<xsl:attribute>指令只会添加到此输出标记中，其后的值会覆盖较早的值。

你必须明确地生成你想要输出的DATA标签，如：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs" version="2.0"> 

    <xsl:output method="xml" indent="yes"/> 
    <xsl:template match="/ENVELOPE"> 
    <Interface> 
     <xsl:apply-templates select="PRODUCT"/> 
    </Interface> 
    </xsl:template> 

    <xsl:template match="PRODUCT"> 
    <xsl:variable name="flag"> 
     <xsl:choose> 
     <xsl:when test="HEAD/FLAG='Yes'">Affirmative</xsl:when> 
     <xsl:when test="HEAD/FLAG='No'">Negative</xsl:when> 
     </xsl:choose> 
    </xsl:variable> 

    <xsl:apply-templates select="BODY/RECORD"> 
     <xsl:with-param name="flag"><xsl:value-of select="$flag"/></xsl:with-param> 
    </xsl:apply-templates> 

    </xsl:template> 

    <xsl:template match="RECORD"> 
    <xsl:param name="flag"/> 
    <Data Value="{Value}" Match="{$flag}"/> 
    </xsl:template> 

</xsl:stylesheet>

来源

2012-04-14 03:33:02

您的第一段非常有意义，谢谢您帮助我了解我出错的位置。 – 2012-04-14 15:49:21

的问题是，你正在创建具有相同名称两个属性 - Value。在格式良好的XML文档中，元素不能具有多个具有相同名称的属性。

引述W3C XSLT 2.0 Specification（这正是在XSLT 1.0相同，太）：

9.如果在结果序列的属性A具有相同的名称出现另一个属性乙稍后在结果序列中，则属性A从结果序列中被丢弃。

因此，无论何时XSLT为一个元素生成多个具有相同名称的属性，只有最后一个属性被复制到输出 - 这就是您所看到的。

下面是一个简短和简单的解决方案（只有两个模板，没有条件句，无参数）：

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 

<xsl:variable name="vDoc" select="/"/> 

<xsl:variable name="vMatch" select= 
"('Affirmative', 'Negative')[2 - number($vDoc/*/*/HEAD/FLAG eq 'Yes')]"/> 

<xsl:template match="/*"> 
    <Interface> 
    <xsl:apply-templates select="*/BODY/RECORD"/> 
    </Interface> 
</xsl:template> 

<xsl:template match="RECORD"> 
    <Data Match="{$vMatch}" Value="{Value}"/> 
</xsl:template> 
</xsl:stylesheet>

当这个变换所提供的XML文档应用：

<ENVELOPE> 
    <PRODUCT> 
     <HEAD> 
      <FLAG>No</FLAG> 
     </HEAD> 
     <BODY> 
      <RECORD> 
       <Value>9</Value> 
      </RECORD> 
      <RECORD> 
       <Value>10</Value> 
      </RECORD> 
      <MISC>9</MISC> 
     </BODY> 
    </PRODUCT> 
</ENVELOPE>

想要的，正确的结果产生：

<Interface> 
    <Data Match="Negative" Value="9"/> 
    <Data Match="Negative" Value="10"/> 
</Interface>

来源

2012-04-14 03:40:39

谢谢Dimitre。我在StackOverflow上学到了很多东西，数组/变量的构造看起来很强大。 – 2012-04-14 15:52:30

@satishb：不客气。 – 2012-04-14 17:06:07

xsl：apply-templates不会遍历选择的每个节点

回答

相关问题