VIM有多于一个的标志

Question

我有一个调试文件看起来像这样折叠：

==>func1: 
..... 
.. 
==>func2: 
...... 
... 
<==func2 
.. 
<==func1 
==>func3: 
...... 
... 
<==func3 

基本上，我想能够折叠的功能，最终看到这样的事情每个人：

+-- x lines: ==> func1: 
+-- x lines: ==> func3: 

，但仍然能够扩大func1，看到func2折叠：

==>func1: 
..... 
.. 
+-- x lines: ==> func2: 
.. 
<==func1 

有没有办法做到这一点？谢谢。

Answer 1

无与伦比的标记需要额外的手柄，这里是一个EXPR溶液（见:h fold-expr）：

setlocal foldmethod=expr 
setlocal foldexpr=GetFoldlevel(v:lnum) 

function GetFoldlevel(lnum) 
    let line = getline(a:lnum) 

    let ret = '=' 
    if line[0:2] == '==>' 
     let name = matchstr(line, '^==>\zs\w*') 
     let has_match = HasMarkerMatch(a:lnum, name) 
     if has_match 
      let ret = 'a1' 
     endif 
    elseif line[0:2] == '<==' 
     let ret ='s1' 
    endif 

    return ret 
endfunction 

function HasMarkerMatch(lnum, name) 
    let endline = line('$') 
    let current = a:lnum + 1 

    let has_match = 0 
    while current <= endline 
     let line = getline(current) 

     if line =~ '^<=='.a:name 
      let has_match = 1 
      break 
     endif 

     let current += 1 
    endwhile 

    return has_match 
endfunction