使用ASP/VBScript写入Excel文件

Question

我想从HTML窗体中获取信息并将其输入到带有ASP/VBScript（不是VB.NET）的Excel文件（xlsx）中。我在Java和PHP方面有一些经验，但对于VB世界来说是新手。 Sofar我已经找到了从GET/POST方法获取数据的方法。现在我正在尝试创建一个到excel文件的ADO连接。 这里是到目前为止我的代码：

Dim cn as ADODB.Connection 
Set cn = New ADODB.Connection 
With cn 
    .Provider = "Microsoft.ACE.OLEDB.12.0" 
    .ConnectionString = "Data Source=EXCEL_FILE.xlsx;" & _"Extended Properties=Excel 12.0 Xml;HDR=YES" 
    .Open 
End With 

我得到了连接字符串从这里：connectionstrings.com 并试图坚持这一指导：http://support.microsoft.com/kb/257819/en-us ，但没有运气，直至现在。 所以这里是我的问题：

1）这是一个正确的想法？因此，例如抓取POST数据，然后打开与ADO的连接到excel文件，并在连接对象上添加查询信息？

2）代码中的任何明显的缺陷？

3）如果有人能够勾画出一个解决方案，将数据从一个HTML表单写入一个Excel文件，那将是非常棒的。

在此先感谢。

编辑： 确定这里是我尝试代码：

Dim cn 
Set cn = Server.CreateObject("ADODB.Connection") 
With cn 
    .Provider = "Microsoft.ACE.OLEDB.12.0" 
    .ConnectionString = "Data Source=EXCEL_FILE.xlsx;Extended Properties=""Excel 12.0 Xml;HDR=YES""" 
'From : http://www.connectionstrings.com/excel-2007 
    .Open 
End With 

一旦我称之为“开放”关于CN它给了我一个500内部错误。我不知道我是否犯了一个明显的错误，但是因为我不知道在哪里可以找到错误日志，所以我不知道从哪里开始寻找。

Answer 1

1 -如果您必须使用Excel 作为数据库，那是对的。但是，如果你需要一个数据库，应该使用数据库，而不是Excel工作表。
2 - VBScript不支持早期绑定。您应该定义没有数据类型的变量，应该使用CreateObject创建对象。而且你需要对连接字符串（引号）进行一些更改。
例如

Dim cn 
Set cn = Server.CreateObject("ADODB.Connection") 
With cn 
    .Provider = "Microsoft.ACE.OLEDB.12.0" 
    .ConnectionString = "Data Source=EXCEL_FILE.xlsx;Extended Properties=""Excel 12.0 Xml;HDR=YES""" 
    'From : http://www.connectionstrings.com/excel-2007 
.Open 
End With 
' 
' Add new records etc. 
' 
cn.Close 
Set cn = Nothing 

3 -一个例子来添加新的记录（把代替上述'Add new records etc.）从HTML表单（POST方法）得到的值。

Dim rs 
Set rs = Server.CreateObject("Adodb.Recordset") 
With rs 
    .Open "[Sheet1$]", cn, 1, 3 
    .AddNew 
    .Fields(0).Value = Request.Form("Param1") 'Column A1 (or with name rs.Fields("col1").Value = exp) 
    .Fields(1).Value = Request.Form("Param2") 'Column B1 
    .Update 
    .Close 
End With 
Set rs = Nothing