SendMessage（WM_COPYDATA）+ Record + String

Question

我想发送一条记录，现在只有一个字符串，但我会添加更多的变量。这是我第一次使用记录，所以这可能是一个愚蠢的问题。但是，为什么这个工程：

type 
    TDataPipe = record 
    WindowTitle: String[255]; 
    end; 

var 
    Data: TDataPipe; 
    copyDataStruct : TCopyDataStruct; 
begin 
    Data.WindowTitle:= String(PChar(HookedMessage.lParam)); 
    copyDataStruct.dwData := 0; 
    copyDataStruct.cbData := SizeOf(Data); 
    copyDataStruct.lpData := @Data; 
    SendMessage(FindWindow('TForm1', nil), WM_COPYDATA, Integer(hInstance), Integer(@copyDataStruct));  
end; 

接收方：

type 
    TDataPipe = record 
    WindowTitle: String[255]; 
    end; 

procedure TForm1.WMCopyData(var Msg: TWMCopyData); 
var 
    sampleRecord : TDataPipe; 
begin 
    sampleRecord.WindowTitle:= TDataPipe(Msg.CopyDataStruct.lpData^).WindowTitle; 
    Memo1.Lines.Add(sampleRecord.WindowTitle); 
end; 

为什么如果在记录，我用：

WindowTitle: String; //removed the fixed size 

，并在发送方使用：

Data.WindowTitle:= PChar(HookedMessage.lParam); //removed String() 

它根本不去？

我得到的访问冲突/应用程序冻结...

的情况是：在发送端是使用SetWindowsHookEx函数迷上一个DLL，接收端一个简单的EXE，它加载/被叫和SetWindowsHookEx ...

Answer 1

一个String[255]是固定的256字节内存块，其中字符数据直接存储在该内存中。因此，不需要序列化就可以跨越流程边界直接传递。

另一方面，String是一种动态类型。它只包含一个指向存储在别处的字符数据的指针。因此，您无法在进程边界上按原样传递String，您只需传递一个指针值，这对接收进程没有任何意义。您必须将String数据序列化为一种可以安全传递给接收进程并进行反序列化的平面格式。例如：

发送方：

type 
    PDataPipe = ^TDataPipe; 
    TDataPipe = record 
    WindowTitleLen: Integer; 
    WindowTitleData: array[0..0] of Char; 
    //WindowTitleData: array[0..WindowTitleLen-1] of Char; 
    end; 

var 
    Wnd: HWND; 
    s: String; 
    Data: PDataPipe; 
    DataLen: Integer; 
    copyDataStruct : TCopyDataStruct; 
begin 
    Wnd := FindWindow('TForm1', nil); 
    if Wnd = 0 then Exit; 

    s := PChar(HookedMessage.lParam); 
    DataLen := SizeOf(Integer) + (SizeOf(Char) * Length(s)); 
    GetMem(Data, DataLen); 
    try 
    Data.WindowTitleLen := Length(s); 
    StrMove(Data.WindowTitleData, PChar(s), Length(s)); 

    copyDataStruct.dwData := ...; // see notes further below 
    copyDataStruct.cbData := DataLen; 
    copyDataStruct.lpData := Data; 
    SendMessage(Wnd, WM_COPYDATA, 0, LPARAM(@copyDataStruct));  
    finally 
    FreeMem(Data); 
    end; 
end; 

接收方：

type 
    PDataPipe = ^TDataPipe; 
    TDataPipe = record 
    WindowTitleLen: Integer; 
    WindowTitleData: array[0..0] of Char; 
    //WindowTitleData: array[0..WindowTitleLen-1] of Char; 
    end; 

procedure TForm1.WMCopyData(var Msg: TWMCopyData); 
var 
    Data: PDataPipe; 
    s: string; 
begin 
    Data := PDataPipe(Msg.CopyDataStruct.lpData); 
    SetString(s, Data.WindowTitleData, Data.WindowTitleLen); 
    Memo1.Lines.Add(s); 
end; 

话虽这么说，在这两种情况下，你真的应该指定自己的自定义ID号到copyDataStruct.dwData领域。 VCL内部使用WM_COPYDATA，所以你不想让这些消息与你的消息混淆，反之亦然。您可以使用RegisterWindowMessage()创建一个唯一的ID，以避免与其他WM_COPYDATA用户使用的ID冲突：

var 
    dwMyCopyDataID: DWORD; 

... 

var 
    ... 
    copyDataStruct : TCopyDataStruct; 
begin 
    ... 
    copyDataStruct.dwData := dwMyCopyDataID; 
    ... 
end; 

... 

initialization 
    dwMyCopyDataID := RegisterWindowMessage('MyCopyDataID'); 

var 
    dwMyCopyDataID: DWORD; 

... 

procedure TForm1.WMCopyData(var Msg: TWMCopyData); 
var 
    ... 
begin 
    if Msg.CopyDataStruct.dwData = dwMyCopyDataID then 
    begin 
    ... 
    end else 
    inherited; 
end; 

... 

initialization 
    dwMyCopyDataID := RegisterWindowMessage('MyCopyDataID'); 

最后的WM_COPYDATA的WPARAM参数是HWND，而不是一个HINSTANCE。如果发件人没有自己的HWND，只需传递0.不要传递发件人的HInstance变量。