我有一个Excel应用程序,我想向用户展示数据源名称列表(即:DSN's),由此他/她可以选择使用什么数据源。如何枚举使用VBA在计算机上设置的DSN列表?
希望一旦我有了清单,我可以轻松地访问DSN属性以连接到适当的数据库。
请注意,我做不是想使用DSN-less连接。
我有一个Excel应用程序,我想向用户展示数据源名称列表(即:DSN's),由此他/她可以选择使用什么数据源。如何枚举使用VBA在计算机上设置的DSN列表?
希望一旦我有了清单,我可以轻松地访问DSN属性以连接到适当的数据库。
请注意,我做不是想使用DSN-less连接。
DSN条目存储在注册表中的以下键中。
HKEY_CURRENT_USER\Software\ODBC\ODBC.INI\ODBC Data Sources HKEY_LOCAL_MACHINE\SOFTWARE\ODBC\ODBC.INI\ODBC Data Sources
这包含所有定义的DSN的列表。这可以作为全局索引和每个DSN的具体细节下存储在密钥与DSN名称:
HKEY_CURRENT_USER\Software\ODBC\ODBC.INI HKEY_LOCAL_MACHINE\SOFTWARE\ODBC\ODBC.INI
创建从数据源两个用户DSN和系统DSN选项卡中某些条目(ODBC)控制面板小程序并检查这些值如何存储在注册表中。
以下示例枚举为用户通过控制面板>管理工具>数据源(ODBC)[用户Dsn选项卡]定义的DSN。
http://support.microsoft.com/kb/178755
Option Explicit
Private Declare Function RegOpenKeyEx Lib "advapi32.dll" _
Alias "RegOpenKeyExA" _
(ByVal hKey As Long, _
ByVal lpSubKey As String, _
ByVal ulOptions As Long, _
ByVal samDesired As Long, phkResult As Long) As Long
Private Declare Function RegEnumValue Lib "advapi32.dll" _
Alias "RegEnumValueA" _
(ByVal hKey As Long, _
ByVal dwIndex As Long, _
ByVal lpValueName As String, _
lpcbValueName As Long, _
ByVal lpReserved As Long, _
lpType As Long, _
lpData As Any, _
lpcbData As Long) As Long
Private Declare Function RegCloseKey Lib "advapi32.dll" _
(ByVal hKey As Long) As Long
Const HKEY_CLASSES_ROOT = &H80000000
Const HKEY_CURRENT_USER = &H80000001
Const HKEY_LOCAL_MACHINE = &H80000002
Const HKEY_USERS = &H80000003
Const ERROR_SUCCESS = 0&
Const SYNCHRONIZE = &H100000
Const STANDARD_RIGHTS_READ = &H20000
Const STANDARD_RIGHTS_WRITE = &H20000
Const STANDARD_RIGHTS_EXECUTE = &H20000
Const STANDARD_RIGHTS_REQUIRED = &HF0000
Const STANDARD_RIGHTS_ALL = &H1F0000
Const KEY_QUERY_VALUE = &H1
Const KEY_SET_VALUE = &H2
Const KEY_CREATE_SUB_KEY = &H4
Const KEY_ENUMERATE_SUB_KEYS = &H8
Const KEY_NOTIFY = &H10
Const KEY_CREATE_LINK = &H20
Const KEY_READ = ((STANDARD_RIGHTS_READ Or _
KEY_QUERY_VALUE Or _
KEY_ENUMERATE_SUB_KEYS Or _
KEY_NOTIFY) And _
(Not SYNCHRONIZE))
Const REG_DWORD = 4
Const REG_BINARY = 3
Const REG_SZ = 1
Private Sub Command1_Click()
Dim lngKeyHandle As Long
Dim lngResult As Long
Dim lngCurIdx As Long
Dim strValue As String
Dim lngValueLen As Long
Dim lngData As Long
Dim lngDataLen As Long
Dim strResult As String
lngResult = RegOpenKeyEx(HKEY_CURRENT_USER, _
"SOFTWARE\ODBC\ODBC.INI\ODBC Data Sources", _
0&, _
KEY_READ, _
lngKeyHandle)
If lngResult <> ERROR_SUCCESS Then
MsgBox "Cannot open key"
Exit Sub
End If
lngCurIdx = 0
Do
lngValueLen = 2000
strValue = String(lngValueLen, 0)
lngDataLen = 2000
lngResult = RegEnumValue(lngKeyHandle, _
lngCurIdx, _
ByVal strValue, _
lngValueLen, _
0&, _
REG_DWORD, _
ByVal lngData, _
lngDataLen)
lngCurIdx = lngCurIdx + 1
If lngResult = ERROR_SUCCESS Then
strResult = strResult & lngCurIdx & ": " & Left(strValue, lngValueLen) & vbCrLf
End If
Loop While lngResult = ERROR_SUCCESS
Call RegCloseKey(lngKeyHandle)
Call MsgBox(strResult, vbInformation)
End Sub
您可以使用ODBC API的SQLDataSources功能。见MSDN documentation。
非常酷的解决方案。我遇到了CURRENT_USER没有显示所有DSN的问题,当然不是我需要的。我将其更改为LOCAL_MACHINE并查看了连接管理器中显示的所有DSN,包括显示在CURRENT_USER下的子集。
http://msdn.microsoft.com/en-us/library/windows/desktop/ms712603(v=vs.85).aspx
很奇妙的答案!它包含背景信息,参考链接和示例代码(这非常好用!)。确切地说,我希望如此工作。非常感谢! – 2008-10-02 23:44:53