wxhaskell异步更新

Question

我正在使用WxHaskell以图形方式显示使用TCP（我使用Data.Binary解码）通告状态更新的程序的状态。收到更新时，我想更新显示。所以我希望GUI以异步方式更新它的显示。我知道processExecAsync异步运行命令行进程，但我不认为这是我想要的。

Answer 1

这是使用事务变量（即软件事务内存）的粗略代码。你可以使用IORef，MVar或其他许多构造。

main = do 
    recvFunc <- initNetwork 
    cntTV <- newTVarIO 0 
    forkIO $ threadA recvFunc cntTV 
    runGUI cntTV 0 

上方启动该程序，初始化网络和共享变量cntTV

threadA recvCntFromNetwork cntTVar = forever $ do 
    cnt <- recvCntFromNetwork 
    atomically (writeTVar cntTVar cnt) 

threadA从网络接收数据和写入计数器的共享变量的新值。

runGUI cntTVar currentCnt = do 
    counter <- initGUI 
    cnt <- atomically $ do 
     cnt <- readTVar cntTVar 
     if (cnt == currentCnt) 
      then retry 
      else return cnt 
    updateGUICounter counter cnt 
    runGUI cntTVar cnt 

runGUI读取共享变量，如果有变化将更新GUI计数器。仅供参考，runGUI线程不会在retry上被唤醒，直到cntTVar被修改，所以这不是一个CPU占用轮询循环。

在这段代码中，我假设你有函数updateGUICounter,initGUI和initNetwork。我建议你使用Hoogle来查找你还不知道的其他功能的位置，并学习一些关于每个模块的知识。

Answer 2

我想出了一种似乎可行的hack。也就是说，使用事件计时器来检查更新队列：

startClient :: IO (TVar [Update]) 
startClient = /*Connect to server, 
       listen for updates and add to queue*/ 

gui :: TVar [Update] -> IO() 
gui trdl = do 
    f <- frame [text := "counter", visible := False] 
    p <- panel f [] 
    st <- staticText p [] 
    t <- timer f [interval := 10, on command := updateGui st] 
    set f [layout := container p $ fill $ widget st, clientSize := (sz 200 100), visible := True] 
where 
    updateGui st = do 
      rdl <- atomically $ readTVar trdl 
      atomically $ writeTVar trdl [] 
      case rdl of 
       [] -> return() 
       dat : dl -> set st [text := (show dat)] 

main :: IO() 
main = startClient >>= start gui 

因此，客户端侦听TCP连接上的更新，将它们添加到队列中。每隔10ms，就会发起一个事件，其操作是检查此队列并在静态文本小部件中显示最新更新。

如果您有更好的解决方案，请告诉我！

Answer 3

我发现在没有忙等待一个解决方案： http://snipplr.com/view/17538/

然而，你可能会为了避免与现有的ID冲突选择更高的事件ID。

这里是我的模块http://code.haskell.org/alsa/gui/src/Common.hs一些代码：

myEventId :: Int 
myEventId = WXCore.wxID_HIGHEST+100 
    -- the custom event ID, avoid clash with Graphics.UI.WXCore.Types.varTopId 

-- | the custom event is registered as a menu event 
createMyEvent :: IO (WXCore.CommandEvent()) 
createMyEvent = 
    WXCore.commandEventCreate WXCore.wxEVT_COMMAND_MENU_SELECTED myEventId 

registerMyEvent :: WXCore.EvtHandler a -> IO() -> IO() 
registerMyEvent win io = 
    WXCore.evtHandlerOnMenuCommand win myEventId io 


reactOnEvent, reactOnEventTimer :: 
    SndSeq.AllowInput mode => 
    Int -> WX.Window a -> Sequencer mode -> 
    (Event.T -> IO()) -> 
    IO() 
reactOnEvent _interval frame (Sequencer h _) action = do 
    mvar <- MVar.newEmptyMVar 

    void $ forkIO $ forever $ do 
     MVar.putMVar mvar =<< Event.input h 
     WXCore.evtHandlerAddPendingEvent frame =<< createMyEvent 

    registerMyEvent frame $ 
     MVar.takeMVar mvar >>= action 

-- naive implementation using a timer, requires Non-Blocking sequencer mode 
reactOnEventTimer interval frame sequ action = 
    void $ 
    WX.timer frame [ 
     WX.interval := interval, 
     on command := getWaitingEvents sequ >>= mapM_ action] 

的代码显示了两种方式来处理这个问题：

• reactOnEventTimer不使用WX定时器忙等待。
• reactOnEvent只有在事件实际到达时才会激活。这是首选解决方案。

在我的例子中，我等待ALSA MIDI音序器消息。 Event.input调用等待下一个ALSA消息。 action获取Event.input的结果，即传入的ALSA消息，但它在WX线程中运行。