在不同时区安排脚本

Question

有些程序/脚本需要在系统时区的不同时区不同的的特定时间运行。

Perl中的crontab，但是在与配置系统的区域不同的区域使用时区和DST规则。

这里是用例：我将创建Excel工作表，在列B中的PT时间和相应的程序/ Perl脚本列C中运行特定关于这个信息在Excel中是

没什么表单 - 也可以是纯文本文件/“crontab”条目。

Perl脚本将读取Excel表格中的数据，并在正确的时间运行/产生这些脚本。

需要注意的是，Perl脚本应该正确运行，而不管运行系统的时区是什么。

无论脚本是在NY或IL或CA的Box上运行，它应该在文件条目中提到的时间根据太平洋标准时间产生脚本，并且在DST的基础上。

正如我之前所说的，它非常重要，它意识到，“自动”（没有我进行任何明确的编程）的PT区域的最新DST规则。

你会建议什么？

也许我可以访问某个网站，显示该地区的当前时间，并从中扫描时间值，并在正确的时间运行脚本？

任何这样的Perl屏幕刮板友好的网站？

或者，也许我可以使用一些智能的Perl模块，如Schedule::Cron

为了记录在案，大量的好的建议在http://www.perlmonks.org/index.pl?node_id=772934走过来，但是，他们，在典型的在/ cron的方式，工作的根据系统配置的时区。

Answer 1

在一般情况下，如果你在乎的时区，在一些通用的格式表示的时间内和转换时间仅用于显示目的。

这适用于您的问题，写一个crontab其次GMT表示。在每台工作机上，转换为本地时间并安装crontab。

前面的问题：

#! /usr/bin/perl 

use warnings; 
use strict; 

use feature qw/ switch /; 

use Time::Local qw/ timegm /; 

对于这个程序支持转换，用今天的日期，并从当前的cronjob替代的​​时间。返回调整小时星期几和偏移：

sub gmtoday { 
    my($gmmin,$gmhr,$gmmday,$gmmon,$gmwday) = @_; 

    my @gmtime = gmtime $^T; 
    my(undef,undef,$hour,$mday,$mon,$year,$wday) = @gmtime; 

    my @args = (
    0, # sec 
    $gmmin eq "*" ? "0" : $gmmin, 
    $gmhr, 
    $mday,       
    $mon, 
    $year, 
); 

    my($lhour,$lwday) = (localtime timegm @args)[2,6]; 

    ($lhour, $lwday - $wday); 
} 

从目前的cronjob以五场时间规范，并从格林尼治标准时间转换为本地时间。请注意，一个完全通用的实现将支持32（即，2 ** 5）的情况。

sub localcron { 
    my($gmmin,$gmhr,$gmmday,$gmmon,$gmwday) = @_; 

    given ("$gmmin,$gmhr,$gmmday,$gmmon,$gmwday") { 
    # trivial case: no adjustment necessary 
    when (/^\d+,\*,\*,\*,\*$/) { 
     return ($gmmin,$gmhr,$gmmday,$gmmon,$gmwday); 
    } 

    # hour and maybe minute 
    when (/^(\d+|\*),\d+,\*,\*,\*$/) { 
     my($lhour) = gmtoday @_; 
     return ($gmmin,$lhour,$gmmday,$gmmon,$gmwday); 
    } 

    # day of week, hour, and maybe minute 
    when (/^(\d+|\*),\d+,\*,\*,\d+$/) { 
     my($lhour,$wdoff) = gmtoday @_; 
     return ($gmmin,$lhour,$gmmday,$gmmon,$gmwday+$wdoff); 
    } 

    default { 
     warn "$0: unhandled case: $gmmin $gmhr $gmmday $gmmon $gmwday"; 
     return; 
    } 
    } 
} 

最后，主循环从输入读取每行并生成相应的输出。请注意，我们不会销毁未处理的时间：它们会作为注释出现在输出中。

while (<>) { 
    if (/^\s*(?:#.*)?$/) { 
    print; 
    next; 
    } 

    chomp; 
    my @gmcron = split " ", $_, 6; 

    my $cmd = pop @gmcron; 
    my @localcron = localcron @gmcron; 

    if (@localcron) { 
    print join(" " => @localcron), "\t", $cmd, "\n" 
    } 
    else { 
    print "# ", $_, "\n"; 
    } 
} 

对于这个八九不离十，crontab的

33 * * * * minute only 
0 0 * * * minute and hour 
0 10 * * 1 minute, hour, and wday (same day) 
0 2 * * 1 minute, hour, and wday (cross day) 

输出以下时，在美国中央时区运行：

33 * * * * minute only 
0 18 * * * minute and hour 
0 4 * * 1 minute, hour, and wday (same day) 
0 20 * * 0 minute, hour, and wday (cross day) 

Answer 2

虽然我当然认为有可能“更清洁”的解决方案，下面的工作会是什么？

• 设置cron来运行脚本几个小时提前可能的范围内，你真正想要倍的脚本运行

• 处理脚本的时区检测，并把它睡适量的时间

再次，我知道这有点kludgey，但我想我会把它放在那里。

Answer 3

在时间表中，存储每个运行应该发生的历元秒数，而不是日期/时间字符串。

扩大一点：

#!/usr/bin/perl 

use strict; use warnings; 

use DateTime; 

my $dt = DateTime->new(
    year => 2010, 
    month => 3, 
    day => 14, 
    hour => 2, 
    minute => 0, 
    second => 0, 
    time_zone => 'America/Chicago', 
); 

print $dt->epoch, "\n"; 

给我

 
Invalid local time for date in time zone: America/Chicago 

因为2:00在2010年3月14日是当发生切换。另一方面，使用hour => 3，我得到：1268553600。现在，在纽约，我使用：

 
C:\Temp> perl -e "print scalar localtime 1268553600" 
Sun Mar 14 04:00:00 2010 

因此，解决方案似乎是避免在本地时区调度过程中不存在的时候，这些事件。这并不需要复杂的逻辑：只要包裹DateTime构造函数调用在eval和处理特殊的时间。

Answer 4

使用datetime模块来计算时间。

所以，如果您的设置表示在凌晨2:30，每天运行脚本，你将需要逻辑：

• 尝试创建一个DateTime对象上午2:30在时区美国\ Los_Angeles。

• 如果没有对象添加5分钟的时间，然后再试一次。 2小时抵消后放弃。

• 一旦你有一个DateTime对象，你可以做的比较与DateTime->now或从对象中提取一个划时代的时间和比较，与time结果。

请注意，我选择了凌晨2:30，因为那段时间至少每年不会有一天存在。这就是为什么你需要一个添加偏移量的循环。