通过VBA在Access前端执行MySQL存储过程

Question

因此，数据库hotchpotch。

• 我有一个存储过程的MySQL数据库。
• 我有一个连接到MySQL数据库（我可以调查表）的Access文件作为前端（与形式和东西）
• 我已经成功创建了一个ODBC通过查询（我认为这就是他们是什么调用）从数据库调用其中一个存储过程。在访问查询实际上只是CALL myProcName;，给我我希望当我Set Result = CurrentDb.OpenRecordset("myProcName")

把它从VBA的结果是什么，我想实现如下：

• 已经在存储过程需要一个参数的MySQL =>检查！
• 让该存储过程按预期工作=>在phpMyAdmin中检查=>检查！
• 在Access中保存了一个查询，该查询链接到此参数存储过程并给定固定参数值=>检查！ （CALL myProcName('myParameterValue')，我可以调用从VBA，就像我做的unparametric查询）
• 必须指定'myParameterValue'每次我执行能力的查询=>不检查

我需要以某种方式指定的参数在保存的查询的SQL定义中添加占位符，并在VBA中设置该参数。对于VBA部分我有和想法，我会发现相当优雅：

Private Sub ParametricQuery() 
    Dim QDef As QueryDef 
    Set QDef = CurrentDb.QueryDefs("myProcName") 
    QDef.Parameters(*insert parameter name here*) = parameter value 
    Dim Result As Recordset 
    Set Result = QDef.OpenRecordset 

    Do While Not Result.EOF 
    MsgBox Result.Fields(1) 'Display a field from the results 
    Loop 
End Sub 

但我将如何建立我的SQL定义？

PARAMETERS in_param TEXT; 
CALL myProcName(in_param); 

不起作用。如果我尝试

Set QDef = CurrentDb.QueryDefs("myProcName") 
MsgBox QDef.Parameters.Count 

我得到一个消息框，告诉我有一个总的在我的查询定义0参数是，这样是行不通的。

我在网上找到的是很多人通过字符串操作在VBA中构建实际的SQL。这让我不寒而栗，原因很多（安全性，可维护性和优雅性）。我坚信有一种更好的方式，希望能够按照我上面所描述的方式。唯一的问题是：如何做到这一点？

Answer 1

考虑使用ADO作为参数化查询来调用存储过程。目前，您正在使用DAO（Access的默认数据库API）来访问传递查询（保存的Access querydef）。但是，这种类型的查询在前端没有看到任何内容，只有后端RDMS，特别是MySQL SQL方言及其连接的数据库对象。因此，您不能将本地参数值绑定到它。而PARAMETERS子句只是Access SQL方言的一部分，并且会失败MySQL语法。

MySQL的存储过程

CREATE PROCEDURE `mystoredproc`(IN param VARCHAR(254)) 
BEGIN 
    SELECT * FROM table WHERE field=param; 
END 

ADO参数化查询

Public Sub CallMySQLProc()  
    Dim conn As Object, cmd As Object, rst As Object 
    Const adCmdStoredProc = 4, adParamInput = 1, adVarChar = 200 

    Set conn = CreateObject("ADODB.Connection") 
    Set rst = CreateObject("ADODB.Recordset") 

    ' DSN-LESS CONNECTION 
    conn.Open "Driver={MySQL ODBC 5.3 Unicode Driver};host=hostname;database=databasename;" _ 
       & "UID=username;PWD=****" 

    ' CONFIGURE ADO COMMAND 
    Set cmd = CreateObject("ADODB.Command") 
    With cmd 
     .ActiveConnection = conn 
     .CommandText = "mystoredproc" 
     .CommandType = adCmdStoredProc 
     .CommandTimeout = 15 
    End With 

    ' APPEND NAMED PARAM 
    cmd.Parameters.Append cmd.CreateParameter("param", adVarChar, _ 
               adParamInput, 254, "some.name@example.com") 
    Set rst = cmd.Execute 

    ' FREE RESOURCES 
    rst.Close 
    Set rst = Nothing 
    Set cmd = Nothing 
    Set conn = Nothing 

End Sub 

---

DAO动态传递查询

在这里，你可以动态生成的QueryDef的.SQL声明，但不会进行参数设置：

Private Sub ParametricQuery() 
    Dim QDef As QueryDef 
    Dim Result As Recordset 

    Set QDef = CurrentDb.QueryDefs("PassThruQ") 
    QDef.SQL = "CALL mystoredproc('some.name@example.com')" 

    Set Result = QDef.OpenRecordset 

    Do While Not Result.EOF 
    Debug.Print Result.Fields(1) 'Print to immediate window a field from the results 
    Loop 

    Result.close 
    Set Result = Nothing 
    Set QDef = Nothing 
End Sub