如何使用Perl将纪元时间转换为UTC时间？

Question

我需要使用Perl将历元日期和时间字符串转换为UTC日期和时间。

请分享您的想法。

#!/usr/bin/perl 
my $start_time='1448841600'; 
my $stop_time='1448863200'; 

上述两个日期和时间是时代格式，应该转换为UTC日期和时间。

Answer 1

您可以使用gmtime做转换，并且strftime做格式化。

use POSIX 'strftime'; 

    strftime "%d-%m-%Y-%H:%M:%S", gmtime('1448841600'); 

Answer 2

使用gmttime获取UTC时间。 http://perldoc.perl.org/functions/gmtime.html

Answer 3

我建议使用Time::Piece模块来操纵日期。

#!/usr/bin/env perl 

use strict; 
use warnings; 

use Time::Piece; 

my $start_time=Time::Piece -> new(1448841600); 


print $start_time,"\n"; 
print $start_time -> epoch,"\n"; 
print $start_time -> strftime ("%Y-%m-%d %H:%M:%S"),"\n"; 

#nb - you can also use localtime/gmtime: 
my $end_time = gmtime(1448863200); 
print $end_time,"\n"; 
print $end_time->epoch,"\n"; 

你也可以做时区数学所列出的位置：How can I parse dates and convert time zones in Perl?

Answer 4

可以使用gmtime功能：

my $time = "1448841600"; 
my @months = ("Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec"); 
my ($sec, $min, $hour, $day,$month,$year) = (gmtime($time))[0,1,2,3,4,5]; 
print "Time ".$time." converts to ".$months[$month]." ".$day.", ".($year+1900); 
print " ".$hour.":".$min.":".$sec."\n"; 

输出：

Time 1448841600 converts to Nov 30, 2015 0:0:0 

Answer 5

如果你需要做的更多在那些日期时间操作，use DateTime

use DateTime; 
my $start_time ='1448841600'; 
my $stop_time ='1448863200'; 
my $start = DateTime->from_epoch(epoch=>$start_time)->set_time_zone('UTC'); 
my $stop = DateTime->from_epoch(epoch=>$stop_time)->set_time_zone('UTC'); 
say $start->strftime("%F %T %Z"); # 2015-11-30 00:00:00 UTC 
say $stop->strftime("%F %T %Z"); # 2015-11-30 06:00:00 UTC