SAS中多种疾病的频率与发病年龄的关系曲线图

Question

我有一组患者的疾病发病年龄数据，我想用不同的线绘出每种疾病发病年龄的频率。 x轴是发病年龄，y轴是频率，每条线代表不同的疾病。年龄0表示患者没有该疾病。 SAS中的代码是做什么的？非常感谢！

HoHTAge HoGDAge AddDAge CelDAge 
0 0 32 0 
0 0 0 0 
12 0 23 0 
0 20 0 0 
25 0 0 0 
0 0 0 0 
32 0 0 0 
0 0 0 0 
0 0 0 0 
0 0 0 0 
0 0 0 0 
0 0 0 35 
45 0 0 0 
0 0 0 0 
0 0 0 0 
43 0 0 0 
0 23 0 0 
0 18 0 0 
0 0 0 0 
0 0 0 0 
0 0 0 0 
0 12 0 0 
30 26 0 0 
0 40 46 0 
0 0 0 30 
57 0 0 0 
0 0 0 0 

Answer 1

不是100％确定如果我明白你的问题是正确的，但我试图提供一个解决方案。

这可能是一个复杂的解决方案，我想有很多简单/简单的解决方案。我算每种疾病的freqs，它们合并到一个数据集，并用gplot吸引他们：

data x; 
input HoHTAge HoGDAge AddDAge CelDAge; 
datalines; 
0 0 32 0 
0 0 0 0 
12 0 23 0 
0 20 0 0 
25 0 0 0 
0 0 0 0 
32 0 0 0 
0 0 0 0 
0 0 0 0 
0 0 0 0 
0 0 0 0 
0 0 0 35 
45 0 0 0 
0 0 0 0 
0 0 0 0 
43 0 0 0 
0 23 0 0 
0 18 0 0 
0 0 0 0 
0 0 0 0 
0 0 0 0 
0 12 0 0 
30 26 0 0 
0 40 46 0 
0 0 0 30 
57 0 0 0 
0 0 0 0 
; 
run; 

proc freq data=x noprint ; 
tables HoHTAge/out=a; 

run; 
proc freq data=x noprint ; 
tables HoGDAge/out=b; 

run; 
proc freq data=x noprint ; 
tables AddDAge/out=c; 

run; 
proc freq data=x noprint ; 
tables CelDAge/out=d; 

run; 

data res (drop =percent count); 
merge a (in=a rename=(HoHTAge=age)) b (in=b rename=(HoGDAge=age)) c (in=c rename=(AddDAge=age)) d(in=d rename=(CelDAge=age)); 
by age; 
*if age=0 then count=0; /*if you want to exclude age 0*/ 
if a then HoHTAge=count; else HoHTAge=0; 
if b then HoGDAge=count; else HoGDAge=0; 
if c then AddDAge=count; else AddDAge=0; 
if d then CelDAge=count; else CelDAge=0; 

ruN; 
/* Set the graphics environment */                          
goptions reset=all cback=white border htext=10pt htitle=12pt; 

axis1 label=("age");               
axis2 label=("Count");                      

symbol1 interpol=join color=R height=14pt font='Arial' ;               
symbol2 interpol=join color=B height=14pt font='Arial';              
symbol3 interpol=join color=O height=14pt font='Arial' ;               
symbol4 interpol=join color=BL height=14pt font='Arial' ;                                                          
legend1 repeat=1 label=none frame;                     

proc gplot data=res;                            
    plot (HoHTAge HoGDAge AddDAge CelDAge)*age/ overlay legend=legend1 haxis=axis1 vaxis=axis2;                   
run;                                  

与样本数据，这将导致这个图，我想用真实的数据，这将更好看，因为现在我们有没有年龄，曾多次针对每种疾病：

作为简单的选择，你可以使用一个Proc频率点阵图，但你必须分隔的图表，只有点，据我了解，你想输出的像长期解决方案：

ods graphics on; 
proc freq data=x ; 
tables HoHTAge HoGDAge AddDAge CelDAge/plots=freqplot(type=dot ORIENT = VERTICAL); 
run;