使用NSIS更新％PATH％环境变量

Question

我读到“字符串长于$ {NSIS_MAX_STRLEN} （1024）将被截断/损坏。”

我怎样才能安全地更新％％PATH环境变量？

Answer 1

您可以使用special builds page中的替代NSIS版本，如large strings build定义NSIS_MAX_STRLEN=8192，并应阻止您破坏主机路径。实际上，在桌面计算机上，1024字节似乎够用了，但是在安装了许多工具的开发主机上（如我的），路径可能会在操作后中断，而8192字节的字符串从未扰乱我的机器。

可以肯定的是，您可以在操作之前在路径长度上添加一个检查，并在路径接近常量NSIS_MAX_STRLEN，然后尝试操纵它，然后用消息中止安装程序。

Answer 2

真正的解决办法是写一个自定义插件或直接与系统插件调用Windows API，因此可以避开NSIS缓冲区长度的限制：

!include LogicLib.nsh 
!include WinCore.nsh 
!ifndef NSIS_CHAR_SIZE 
!define NSIS_CHAR_SIZE 1 
!endif 

Function RegAppendString 
System::Store S 
Pop $R0 ; append 
Pop $R1 ; separator 
Pop $R2 ; reg value 
Pop $R3 ; reg path 
Pop $R4 ; reg hkey 
System::Call 'ADVAPI32::RegCreateKey(i$R4,tR3,*i.r1)i.r0' 
${If} $0 = 0 
    System::Call 'ADVAPI32::RegQueryValueEx(ir1,tR2,i0,*i.r2,i0,*i0r3)i.r0' 
    ${If} $0 <> 0 
     StrCpy $2 ${REG_SZ} 
     StrCpy $3 0 
    ${EndIf} 
    StrLen $4 $R0 
    StrLen $5 $R1 
    IntOp $4 $4 + $5 
    IntOp $4 $4 + 1 ; For \0 
    !if ${NSIS_CHAR_SIZE} > 1 
     IntOp $4 $4 * ${NSIS_CHAR_SIZE} 
    !endif 
    IntOp $4 $4 + $3 
    System::Alloc $4 
    System::Call 'ADVAPI32::RegQueryValueEx(ir1,tR2,i0,i0,isr9,*ir4r4)i.r0' 
    ${If} $0 = 0 
    ${OrIf} $0 = ${ERROR_FILE_NOT_FOUND} 
     System::Call 'KERNEL32::lstrlen(t)(ir9)i.r0' 
     ${If} $0 <> 0 
      System::Call 'KERNEL32::lstrcat(t)(ir9,tR1)' 
     ${EndIf} 
     System::Call 'KERNEL32::lstrcat(t)(ir9,tR0)' 
     System::Call 'KERNEL32::lstrlen(t)(ir9)i.r0' 
     IntOp $0 $0 + 1 
     !if ${NSIS_CHAR_SIZE} > 1 
      IntOp $0 $0 * ${NSIS_CHAR_SIZE} 
     !endif 
     System::Call 'ADVAPI32::RegSetValueEx(ir1,tR2,i0,ir2,ir9,ir0)i.r0' 
    ${EndIf} 
    System::Free $9 
    System::Call 'ADVAPI32::RegCloseKey(ir1)' 
${EndIf} 
Push $0 
System::Store L 
FunctionEnd 

Section 

Push ${HKEY_CURRENT_USER} 
Push "Environment" 
Push "Path" 
Push ";" 
Push "c:\whatever" 
Call RegAppendString 
Pop $0 
DetailPrint RegAppendString:Error=$0 

SectionEnd 

Answer 3

我已经写了NSIS 3.0例子来处理案件超过限制，无需安装任何东西。回答了这个问题在这里：Set environment variables with NSIS in Window 7

Answer 4

我更喜欢通过NSIS nsExec::Exec命令，它允许你要追加到PATH容易，像这样使用Windows命令处理器（cmd.exe）：

; Check if the path entry already exists and write result to $0 
nsExec::Exec 'echo %PATH% | find "c:\some\new\dir"' 
Pop $0 ; gets result code 

${If} $0 = 0 
    nsExec::Exec 'set PATH=%PATH%;c:\some\new\dir' 
${EndIf} 

使用这种方法，CMD.EXE扩张内部变量PATH，不受任何NSIS字符串长度限制的影响。

nsExec::Exec 'set PATH=c:\some\new\dir;%PATH%' 

还要注意的是：另外，如果你想被拾起你的程序第一，任何事情和其他一切可能对系统由同名安装提前改变%PATH%标记粘贴顺序不包括双引号，而建设新PATH是很重要的。命令处理器从不期望PATH字符串中的双引号，如果添加任何内容，可能会以意想不到的方式运行。它仅用分号（;）分隔路径。

nsExec::Exec从ExecWait不同之处在于它在内部运行，没有弹出额外可见命令提示符窗口。