如何在Access数据库中列出DataMacro对象？

Question

是否有可能以编程方式枚举Access 2010+数据库中的数据宏？如果是这样，怎么样？

---

注意：Data Macros是在表设计UI的上下文中创建触发器的类似程序。它们在Acces 2010中是新的。它们与通常的宏不同，它们很容易枚举。

他们有自己的新AcObjectType枚举值：acTableDataMacro，但我没有发现指向它们的Access或DAO对象模型的其他方面。它们甚至不出现在MSysObjects表中。

Answer 1

此代码将DataMacro元数据导出到一个XML文档（Source）：

Sub DocumentDataMacros() 

'loop through all tables with data macros 
'write data macros to external files 
'open folder with files when done 

' click HERE 
' press F5 to Run! 

' Crystal 
' April 2010 

On Error GoTo Proc_Err 

' declare variables 
Dim db As DAO.Database _ 
, r As DAO.Recordset 

Dim sPath As String _ 
, sPathFile As String _ 
, s As String 

' assign variables 
Set db = CurrentDb 

sPath = CurrentProject.Path & "\" 

s = "SELECT [Name] FROM MSysObjects WHERE Not IsNull(LvExtra) and Type =1" 

Set r = db.OpenRecordset(s, dbOpenSnapshot) 

' loop through all records until the end 
Do While Not r.EOF 
sPathFile = sPath & r!Name & "_DataMacros.xml" 
'Big thanks to Wayne Phillips for figuring out how to do this! 
SaveAsText acTableDataMacro, r!Name, sPathFile 
'have not tested SaveAsAXL -- please share information if you do 
r.MoveNext 
Loop 

' give user a message 
MsgBox "Done documenting data macros for " & r.RecordCount & " tables ", , "Done" 

Application.FollowHyperlink CurrentProject.Path 

Proc_Exit: 
' close and release object variables 
If Not r Is Nothing Then 
r.Close 
Set r = Nothing 
End If 

Set db = Nothing 
Exit Sub 

Proc_Err: 
MsgBox Err.Description, , _ 
"ERROR " & Err.Number _ 
& " DocumentDataMacros" 

Resume Proc_Exit 
Resume 

End Sub 

编辑：戈德指出，你想反对标准宏DataMacros。我发现了一些代码并进行了测试（它的工作原理）here

我测试了顶级函数，当您遵循该链接时，它保存了XML文档中每个表的关于表宏的信息。它很好地工作，支持写它的人。