说服火狐解析嵌入XML（应用XSL后）HTML

我有这种形式的一些XML文件：说服火狐解析嵌入XML（应用XSL后）HTML

<?xml version="1.0" encoding="utf-8"?> 
<?xml-stylesheet type="text/xsl" href="biomirror.xsl"?> 
<Thread> 
    <Title> Some thread title </Title> 
    <Posts> 
     <Post> 
      <Author> Me </Author> 
      <Body> 
       This is the post body, which <b>may</b> have embedded XHTML, including all sorts of things like:<br /> 
       <div class="quote">Quotes</div> 
       I know it's XHTML, though, the program spitting out XML verifies that. 
      </Body> 
     </Post> 
    </Posts> 
</Thread>

我需要把它们格式化成可读的线程，所以我使用一个CSS样式表和一个XSL样式表。 CSS的作品，我知道有一个事实，没有什么不妥。我的问题似乎与XSL一样，因为任何嵌入式XHTML都不会被Firefox解析。在IE浏览器中，它完美地工作，并以适当的格式出现，但在Firefox中它完全是纯文本格式。我认为这与它在输出前被转义有关，但我无法弄清楚如何防止这种情况。

XSL是：

<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output 
    omit-xml-declaration="yes" 
    method="xml" 
    media-type="application/xhtml+xml" 
    indent="no" 
    doctype-public="-//W3C//DTD XHTML 1.0 Transitional//EN" 
/> 
<xsl:template match="Posts"> 
<xsl:for-each select="Post"> 
    <tr xmlns="http://www.w3.org/1999/xhtml" class="Post"> 
     <td> 
     <div> 
      <table width="100%" cellpadding="0" cellspacing="0"> 
      <tr> 
       <td class="Author"> 
       <xsl:value-of select="Author"/> 
       </td> 
       <td class="Date"> 
       Post <xsl:value-of select="PostID"/> 
       <xsl:choose> 
        <xsl:when test="count(LastPost) > 0"> 
        (lastpost) 
        </xsl:when> 
       </xsl:choose> at <xsl:value-of select="Date"/> 
       </td> 
      </tr> 
      </table> 
     </div> 
     <div class="Body"> 
      <xsl:copy-of select="Body" /> 
     </div> 
     <xsl:choose> 
      <xsl:when test="count(Sig) = 1"> 
      <div class="Sig"> 
       <xsl:value-of disable-output-escaping="yes" select="Sig"/> 
      </div> 
      </xsl:when> 
      <xsl:when test="count(Sig) = 0"> 
      <div class="SigFooter"> </div> 
      </xsl:when> 
     </xsl:choose> 
     </td> 
    </tr> 
</xsl:for-each> 
</xsl:template> 

<xsl:template match="Thread"> 
    <html xmlns="http://www.w3.org/1999/xhtml"> 
    <head> 
     <xsl:choose> 
      <xsl:when test="count(Title) = 1"> 
      <title> 
       <xsl:value-of select="Title"/> 
      </title> 
      </xsl:when> 
     </xsl:choose> 
     <link href="resources/main.css" rel="stylesheet" type="text/css" /> 
    </head> 
    <body> 
     <table class="Thread" align="center" width="90%" height="95%" cellpadding="2em"> 
     <tr> 
      <td colspan="3"> 
      <div class="Title"> 
      <xsl:value-of select="Title"/> 
       <br /> 
       <a href="whatis.xml"> 
       <img src="resources/banner.png" /> 
       </a> 
      </div> 
      </td> 
     </tr> 
     <xsl:apply-templates select="Posts"/> 
     <tr height="100%"> 
     <td valign="bottom"> 
     <div class="Footer"> 
      Footer message n stuff 
      </div> 
     </td> 
     </tr> 
     </table> 
    </body> 
    </html> 
</xsl:template>

这是一个黑客位和任何奇怪的属性，我在Visual Studio中指责的。这是我第一次使用XSL（对XML比较熟悉），所以我不知道该怎么做才能解决这个问题。 :)

现在，我读了这个问题： XSLT: Parsing HTML embedded in XML? 并试图将它集成到我的XML和XSL（如上所示）。尽管如此，Firefox仍然不起作用。

编辑：另外，我尝试了xsl：value-of和xsl：copy-of来输出内容。值的输出纯文本和尊重我的格式（从CSS），复制输出纯文本和废墟我的格式（退回到正文格式，无视div和表）。

编辑2：修订XSL以反映答案的建议。格式化很好，但嵌入的标签仍然以文本出现，而不是被解释。

来源

2010-07-16 ssube

首先，你不需要这些声明：

xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"

它的安全删除它们。

其次，你永远不需要提及child::轴。这在XSLT中是隐含的，只是将其踢出而不替换。

三，移动XHTML命名空间声明

xmlns="http://www.w3.org/1999/xhtml"

到<xsl:stylesheet>元素和其他地方将其删除。

最后但并非最不重要：您是否尝试过XHTML的正确输出方法和媒体类型？

<xsl:output method="xml" media-type="application/xhtml+xml">

来源

2010-07-16 21:19:14 Tomalak

哦，还：CSS在标准渲染模式下区分大小写。请仔细检查您的班级名称是否正确。 – Tomalak 2010-07-16 21:22:56

我的班级名称是正确的，看起来像。我只是尝试了所有的建议。它解决了复制忽略样式的问题，但在页面周围引入了一个薄白色边框，但仍未修复XHTML未被解释为这样的问题。 – ssube 2010-07-16 21:42:31

@peachy：这些只是建议。你做客户端XSLT处理？ – Tomalak 2010-07-16 21:55:36

第一：我用Firefox 3.5.9运行此。它没有问题，但这是错误的。

当你说：

<xsl:copy-of select="child::Body" />

您应对其内容的非命名空间元素。而且因为你没有用XHTML命名空间声明这些内容，所以这些不是XHTML元素。他们应该有一个xmlns=""声明。但是我的Firefox版本做错了事：没有将命名空间元素（例如b）解释为XHTML元素（没有空的命名空间！）。由于您没有提供CSS样式表，因此我无法进行CSS测试（如果没有名称空间元素获取样式）。

编辑：MSXSL正确xmlns=""声明增加了在Body，但随后呈现IE无论MS想。 JA！

来源

2010-07-16 22:22:25

我刚刚编辑帖子以反映来自其他答案的建议。样式很好，我认为所有的样式表问题都是固定的。无论哪种方式，我可以自己调试CSS没问题，我只是不熟悉XSL。我删除了child :: parts。但是，在Firefox 3.6.6中，它不起作用。你是说用XHTML命名空间声明内容是什么？ – ssube 2010-07-16 22:30:41

@peachykeen：你需要在输入中的'Body'元素中添加一个默认的名称空间声明为'xmlns =“http://www.w3.org/1999/xhtml”'，同时在这个名字空间中定义一个前缀样式表作为'xmlns：xhtml =“http://www.w3.org/1999/xhtml”'并使用'xhtml：Body/node（）'xpath选择'Body'元素内容。 – 2010-07-16 22:37:59

刚刚尝试过，仍然没有解析FF 3.6.6中的嵌入式XHTML。不过，如果我误解了你的话，我会继续努力。 – ssube 2010-07-16 23:18:42

您的XML输入确实是而不是已嵌入XHTML，因为这需要那些您希望被识别为XHTML的元素位于XHTML名称空间http://www.w3.org/1999/xhtml中。因此，您需要更改输入以将这些元素放入XHTML名称空间中，然后确实可以简单地将它们复制到样式表中的结果树中，或者需要更改样式表以将这些元素转换为XHTML名称空间中的元素。以下是，也做了一些其他更改，如设置版本=“1.0”：

<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns="http://www.w3.org/1999/xhtml"> 
<xsl:output 
    omit-xml-declaration="yes" 
    method="xml" 
    media-type="application/xhtml+xml" 
    indent="no" 
    doctype-public="-//W3C//DTD XHTML 1.0 Transitional//EN" 
/> 
<xsl:template match="Posts"> 
<xsl:for-each select="Post"> 
    <tr class="Post"> 
     <td> 
     <div> 
      <table width="100%" cellpadding="0" cellspacing="0"> 
      <tr> 
       <td class="Author"> 
       <xsl:value-of select="Author"/> 
       </td> 
       <td class="Date"> 
       Post <xsl:value-of select="PostID"/> 
       <xsl:choose> 
        <xsl:when test="count(LastPost) > 0"> 
        (lastpost) 
        </xsl:when> 
       </xsl:choose> at <xsl:value-of select="Date"/> 
       </td> 
      </tr> 
      </table> 
     </div> 
     <div class="Body"> 
      <xsl:apply-templates mode="to-xhtml" /> 
     </div> 
     <xsl:choose> 
      <xsl:when test="count(Sig) = 1"> 
      <div class="Sig"> 
       <xsl:value-of disable-output-escaping="yes" select="Sig"/> 
      </div> 
      </xsl:when> 
      <xsl:when test="count(Sig) = 0"> 
      <div class="SigFooter"> </div> 
      </xsl:when> 
     </xsl:choose> 
     </td> 
    </tr> 
</xsl:for-each> 
</xsl:template> 

<xsl:template match="Thread"> 
    <html> 
    <head> 
     <xsl:choose> 
      <xsl:when test="count(Title) = 1"> 
      <title> 
       <xsl:value-of select="Title"/> 
      </title> 
      </xsl:when> 
     </xsl:choose> 
     <link href="resources/main.css" rel="stylesheet" type="text/css" /> 
    </head> 
    <body> 
     <table class="Thread" align="center" width="90%" height="95%" cellpadding="2em"> 
     <tr> 
      <td colspan="3"> 
      <div class="Title"> 
      <xsl:value-of select="Title"/> 
       <br /> 
       <a href="whatis.xml"> 
       <img src="resources/banner.png" /> 
       </a> 
      </div> 
      </td> 
     </tr> 
     <xsl:apply-templates select="Posts"/> 
     <tr height="100%"> 
     <td valign="bottom"> 
     <div class="Footer"> 
      Footer message n stuff 
      </div> 
     </td> 
     </tr> 
     </table> 
    </body> 
    </html> 
</xsl:template> 

    <xsl:template match="*" mode="to-xhtml"> 
    <xsl:element name="{local-name()}"> 
     <xsl:apply-templates select="@* | node()" mode="to-xhtml"/> 
    </xsl:element> 
    </xsl:template> 

    <xsl:template match="@* | text() | processing-instruction() | comment()" mode="to-xhtml"> 
    <xsl:copy/> 
    </xsl:template> 

</xsl:stylesheet>

来源

2010-07-17 13:10:44

说服火狐解析嵌入XML（应用XSL后）HTML

回答

相关问题