自定义组件和标签顺序

Question

我有一个自定义组件（继承自TCustomPanel），它由两个其他组件（假设两个编辑）组成。如何在使用组件时正确地获取Tab键顺序？

在Tab键顺序设计器中，我只能访问组件本身，因为它是一个面板，所以不能拥有焦点。运行时会发生什么情况是，我可以使用Tab键访问编辑，但只有在组件下方的两个按钮得到了重点之后才能访问。

如何在这种情况下更改标签顺序？

Answer 1

组件中嵌套控件的Tab顺序不同于组件所在表单的Tab顺序。当您选择嵌套控件时，表单的标签顺序列表中组件的标签顺序。一旦所有选项卡顺序列表组合时，它们导致最终循环：

• 窗体上的控制（TabOrder=0）
• 另一个上表单控件（TabOrder=1）
• 你的面板部件（TabOrder=2）
  • 编辑1（TabOrder=0）
  • 编辑2（TabOrder=1）
• 上形式的另一个控制（TabOrder=3）

---

为了能够设置的面板构件设计时的Tab键顺序：

• 使用在设计选项卡顺序编辑器（右键点击在组件的父级上），并使用编辑器中的箭头更改Tab键顺序，或者

• 发布组件的TabOrder属性并将其设置在对象检查器中：

  type 
      TMyPanel = class(TCustomPanel) 
      published 
      property TabOrder; 
      end; 
  

在运行时，它总是可以设置组件的选项卡顺序，因为TabOrder属性声明公众TWinControl。

...因为是面板所以不能集中注意力。

不，面板可以重点聚焦就好，但不会默认。这是通过TabStop属性处理的，默认为False。您不希望TabStop为您的组件设置True，因为（1）面板没有指示器，它具有焦点，（2）它不是我想要的（我想象）。

---

更改嵌套控件的Tab顺序最好在组件的构造函数或运行时完成。

为了能够在设计时设置组件内嵌套控件的Tab顺序，需要做更多的工作。 我不认为你想这样做，但由于我以前的答案（删除）是垃圾（并且蛮横地投票），我已经制定了一个例子作为补偿。

首先，请注意，使用设计器中的Tab键顺序编辑器（右键单击面板组件）设置这些编辑的Tab键顺序将更改Tab键顺序，但不会持续。这是因为这些更改没有流式传输到DFM。

为了能够流/保存控件的设计时间的变化，你需要把它们发布：

type 
    TMyPanel = class(TCustomPanel) 
    private 
    FEdit1: TEdit; 
    FEdit2: TEdit; 
    public 
    constructor Create(AOwner: TComponent); override; 
    published 
    property Edit1: TEdit read FEdit1; 
    property Edit2: TEdit read FEdit2; 
    end; 

constructor TMyPanel.Create(AOwner: TComponent); 
begin 
    inherited Create(AOwner); 
    FEdit1 := TEdit.Create(Self); 
    FEdit1.SetBounds(10, 10, 100, 21); 
    FEdit1.Name := 'Edit1'; 
    FEdit1.Parent := Self; 
    FEdit1.SetSubComponent(True); 
    FEdit2 := TEdit.Create(Self); 
    FEdit2.SetBounds(10, 41, 100, 21); 
    FEdit2.Name := 'Edit2'; 
    FEdit2.Parent := Self; 
    FEdit2.SetSubComponent(True); 
end; 

当然这个发布这些控件的所有属性，现在用户可以更改为所欲为。为了防止这种情况，考虑限制TEdit控件的发布性能：

unit MyPanelEdit; 

interface 

uses 
    DesignEditors, Unit2, DesignIntf, SysUtils, Classes, TypInfo, StdCtrls; 

type 
    TEditProperty = class(TComponentProperty) 
    private 
    function FilterFunc(const ATestEditor: IProperty): Boolean; 
    public 
    function GetAttributes: TPropertyAttributes; override; 
    procedure GetProperties(Proc: TGetPropProc); override; 
    end; 

procedure Register; 

implementation 

procedure Register; 
begin 
    RegisterPropertyEditor(TypeInfo(TEdit), TMyPanel, '', TEditProperty); 
end; 

{ TEditProperty } 

function TEditProperty.FilterFunc(const ATestEditor: IProperty): Boolean; 
begin 
    Result := ATestEditor.GetName = 'TabOrder'; 
end; 

function TEditProperty.GetAttributes: TPropertyAttributes; 
begin 
    Result := [paSubProperties]; 
end; 

procedure TEditProperty.GetProperties(Proc: TGetPropProc); 
var 
    LComponents: IDesignerSelections; 
    LDesigner: IDesigner; 
begin 
    LComponents := GetSelections; 
    if LComponents <> nil then 
    begin 
    if not Supports(
     FindRootDesigner(LComponents[0]), IDesigner, LDesigner) then 
     LDesigner := Designer; 
    GetComponentProperties(LComponents, [tkInteger], LDesigner, Proc, 
     FilterFunc); 
    end; 
end; 

end. 

这限制了出版TEdit属性的属性唯一TabOrder显现。