查找存在于一个地图中但不在另一个地图中的键

Question

我有2个地图。有什么方法可以找出Map中存在哪些密钥，但它们在另一个中不存在？

Answer 1

使用Map.keys/1与--是做到这一点的最简单的方法：

# Suppose your two maps are: 
map_a = %{a: 1, b: 2, c: 3, d: 4} 
map_b = %{c: 3, d: 4, e: 5, f: 6} 


# Get keys present in map_a but not in map_b 
a_b_diff = Map.keys(map_a) -- Map.keys(map_b)  # => [:a, :b] 


# Get keys present in map_b but not in map_a 
b_a_diff = Map.keys(map_b) -- Map.keys(map_a)  # => [:e, :f] 

Answer 2

--是大型列表极其低效。由于您已经拥有地图，因此您可以使用Map.has_key?/2查找O(log n)时间内任意键的存在。一个简单的for有过滤器可以用来获得你想要的结果：

iex(1)> map1 = %{a: 1, b: 2, d: 3, f: 4} 
%{a: 1, b: 2, d: 3, f: 4} 
iex(2)> map2 = %{b: 5, c: 6, f: 7, g: 8} 
%{b: 5, c: 6, f: 7, g: 8} 
iex(3)> for {k, _} <- map1, !Map.has_key?(map2, k), do: k 
[:a, :d] 

快速基准与大地图显示了巨大的性能差异VS Kernel.--/2：

map1 = for x <- Enum.take_random(1..10000, 5000), into: %{}, do: {x, x} 
map2 = for x <- Enum.take_random(1..10000, 5000), into: %{}, do: {x, x} 

{time, result1} = :timer.tc(fn -> 
    Map.keys(map1) -- Map.keys(map2) 
end) 
IO.puts "--: #{time}µs" 

{time, result2} = :timer.tc(fn -> 
    for {k, _} <- map1, !Map.has_key?(map2, k), do: k 
end) 
IO.puts "for: #{time}µs" 

IO.inspect result1 == result2 

输出：

--: 113367µs 
for: 739µs 
true 

如果你的地图虽然很小，但是--肯定比这个短一些，可读性也应该足够好。