Gnuplot - 用两个命令迭代

Question

我试图用一个只包含0或1的简单数据文件（.example）构建一种条形图。这里包含的数据.example：

dest P1 P2 P3 P4 P5 NA 
D1 0 1 1 0 0 0 
D2 0 0 1 0 0 0 
D3 0 1 0 1 0 0 
"" 
GPV 1 1 1 1 1 1 

，这里是我使用的代码：

set style histogram rowstacked title textcolor lt -1 
set datafile missing 'nan' 
set style data histograms 

plot '.example' using ($2==0 ? 1 : 0) ls 17 title 'NA', \ 
'' using ($2==1 ? 1 : 0) ls 1, \ 
for [i=3:5] '.example' using (column(i)==0 ? 1 : 0) ls 17 notitle, \ 
for [i=3:5] '' using (column(i)==1 ? 1 : 0) ls i-1 

其中最后两个命令遍历一个潜在的大量 列堆叠白色或彩色的取决于column(i)的值。要保持直方图中不同列的颜色顺序相同，我需要将两个迭代合并为一个包含两个命令的迭代。

可能吗？有关如何做到这一点的任何建议？

Answer 1

您可以使用嵌套循环，我认为这是您想要实现的。您可以使用迭代遍历大量列的外部循环和遍历两个选项（白色或彩色）的内部循环（for [i=3:5] for [j=0:1]），并告诉gnuplot忽略该列，前提是其内容与j的值不匹配1/0（或使用的伎俩，有效的直方图，将其设置为0作为你已经做）：

set style histogram rowstacked title textcolor lt -1 
set datafile missing 'nan' 
set style data histograms 

plot '.example' using ($2==0 ? 1 : 0) ls 17 title 'NA', \ 
'' using ($2==1 ? 1 : 0) ls 1, \ 
for [i=3:5] for [j=0:1] '.example' using (column(i) == j ? 1 : 0) \ 
ls (j == 0 ? 17 : i-1) notitle 

上面的代码就相当于你有什么已经，只有j值允许开关样式取决于您是否有0或1作为列的值。