VBA匹配工作表名称到文本列表

Question

我有一个城市名称的文本列表，我需要检查并查看这些名称是否为工作表的名称，以及是否不使用所述名称创建新的工作表。

另一方面，如果在列表中没有任何名称的工作表，那么我需要删除这些工作表。

我一直在尝试这个问题几个小时，我很失落，它可能是简单的东西，所以如果有人可以帮助，将非常感激！

Answer 1

下面是关于这个代码的代码。这是我的文本文件的样子，所以没有混淆。

Sub Macro1() 
Dim sFileName, tmp As String 
Dim dict As New Dictionary 
Dim dictCopy As New Dictionary 
Dim ws As Worksheet 

sFileName = "C:\Users\Mango\Desktop\names.txt" 
'^ Specify the location of the txt file that you want read 

    With New Scripting.FileSystemObject 
     With .OpenTextFile(sFileName, ForReading) 

      Do Until .AtEndOfStream 
       tmp = .ReadLine 
       '^ This step should be noted. Calling .Readline more than once 
       ' even in loop cause it to move to the next one. 

       dict.Add tmp, tmp 
       dictCopy.Add tmp, tmp 
       '^ add to our dictionary objects 
      Loop 

     End With 
    End With 

这是我在这里拿起形式的文本阅读代码：Read lines from a text file but skip the first two lines。我发现它比其他vba文本阅读代码更优雅。但是，您需要选择一个“Microsoft脚本运行时”作为参考（从工具菜单中）才能使用它。此代码还使用Dictionary对象，该对象还需要该引用才能使用它。我使用这个对象而不是数组或其他集合，原因我将在下面解释。

For Each ws In ActiveWorkbook.Worksheets 
    If dict.Exists(ws.Name) = True Then 
     dict.Remove (ws.Name) 
    End If 
Next 

For Each j In dict.Items 
    Set ws = Worksheets.Add(after:=Worksheets(Worksheets.Count)) 
    ws.Name = j 
Next 

根据您的名单有多长，你可能会发现Dictionary对象利于双循环等。这是因为它有.Exists方法来查看它是否包含其中的特定值。我不知道它里面的机制，但它比双循环技术更快，尤其是当你有很多条目要比较时。你应该注意到很多这些字典方法都使用了关键字info（而不是值）。

最后一部分：

Application.DisplayAlerts = False 'removes annoying save notification 
    For Each ws In ActiveWorkbook.Worksheets 
     If dictCopy.Exists(ws.Name) = False Then 
      ws.Delete 
     End If 
    Next 
    Application.DisplayAlerts = True 
End Sub 

我选择了做它喜欢这样，因为Excel将不允许您删除最后一个表中的工作簿。因此，如果您选择删除错误命名的工作表或者至少合并该方法，那么如果没有任何工作表名称集合在集合中，则必须删除所有这些工作表。