遍历矢量树

Question

欲遍历表示打嗝数据结构的载体树：

[:div {:class "special"} [:btn-grp '("Hello" "Hi")]] 

然后我想派遣于载体上的关键字，如果多重方法已为关键字定义，然后它会返回另一组矢量，它将替换原始标记。

例如，上述结构会被变换为：

[:div {:class "special"} [:div [:button "Hello"] [:button "Hi"]]] 

定制多重方法将收到列表（“你好”，“喜”）作为参数。它会返回包含按钮的div。

我如何写穿越载体与形式作为参数一切分派的关键字，然后返回的形式代替当前形式的功能？

Answer 1

(ns customtags 
    (:require [clojure.walk :as walk])) 

(def customtags (atom {})) 

(defn add-custom-tag [tag f] 
    (swap! customtags assoc tag f)) 

(defn try-transform [[tag & params :as coll]] 
    (if-let [f (get @customtags tag)] 
    (apply f params) 
    coll)) 

(defmacro defcustomtag [tag params & body] 
    `(add-custom-tag ~tag (fn ~params ~@body))) 

(defn apply-custom-tags [coll] 
    (walk/prewalk 
    (fn [x] 
     (if (vector? x) 
     (try-transform x) 
     x)) coll)) 

使用它：

(require '[customtags :as ct]) 
(ct/defcustomtag :btn-grp [& coll] (into [:div] (map (fn [x] [:button x]) coll))) 
(ct/defcustomtag :button [name] [:input {:type "button" :id name}]) 

(def data [:div {:class "special"} [:btn-grp "Hello" "Hi"]]) 

(ct/apply-custom-tags data) 
[:div {:class "special"} [:div [:input {:type "button", :id "Hello"}] [:input {:type "button", :id "Hi"}]]]