文件分割成多个文件写2种模式之间的线路到一个新的文件

Question

这是输入文件：

#cat myfile 
-- START 
whatever 
whatever 
-- END 

-- START 
whatever 
whatever 
-- END 

-- START 
whatever 
whatever 
-- END 

-- START 
whatever 
whatever 
-- END 

我需要抓住-- START和-- END之间行写这些行到一个单独的文件。因此，在这个用例，我应该已经创建如下4个文件：

# cat file1 
whatever 
whatever 

# cat file2 
whatever 
whatever 

# cat file3 
whatever 
whatever 

# cat file4 
whatever 
whatever 

这里是我的代码：

#!/usr/bin/perl 
use strict; 
use warnings; 

open (my $fh, "<", "/var/tmp/myfile"); 
my $counter = 0; 

while (<$fh>) 
{ 
    if (/START/../END/) 
    { 
     my $filename = "/var/tmp/file".$counter; 
     open (my $oh, ">", $filename); 
     print $oh $_; 
    } 
    $counter++; 
} 

问题：我的代码是创建一个文件每个线在-- START和-- END内发现

你能帮我弄清楚如何解决这段代码。谢谢。

Answer 1

而不是打开每个行的新文件，它应该打开每个范围的开始。

使用范围的返回值来确定何时打开文件并只打印边界条件之间的那些线。

my $oh; 
while (<$fh>) { 
    if (my $range = /START/ .. /END/) { 
     # Start of Range - Open the file handle 
     if ($range == 1) { 
      my $filename = "/var/tmp/file" . $counter++; 
      open($oh, ">", $filename) or die $!; 

     # Print until End of Range 
     } elsif ($range !~ /E/) { 
      print $oh $_; 
     } 
    } 
} 

Answer 2

您可以将输入分隔符设置为您的“ - END”标记，以便以“ - END”分隔的块读入文件。然后可以使用正则表达式来捕获所需的信息。我注释掉你我的文件/ O线和使用本地数据，因此可以运行代码，以检查它的工作原理：

#!/usr/bin/perl 
use strict; 
use warnings; 
use feature ":5.10"; 
use Data::Dumper; 

#open (my $fh, "<", "/var/tmp/myfile"); 
my $counter = 0; 

$/ = "-- END"; 
# while (<$fh>) 
while (<DATA>) 
{ if (/START\s*(\S.+?)\s*-- END/ms) 
    { 
    # my $filename = "/var/tmp/file".$counter; 
    # open (my $oh, ">", $filename); 
    # print $oh $1; 
     say "file $counter\n$1"; 
     $counter++; 
    } 
} 

__DATA__ 

-- START 
whatever1 
whatever2 
-- END 

-- START 
whatever3 
whatever4 
-- END 

-- START 
whatever5 
whatever6 
-- END 

-- START 
whatever7 
whatever8 
-- END 

输出（去STDERR，但很明显，你会取消对读取线和写入文件）：

file 0 
whatever1 
whatever2 
file 1 
whatever3 
whatever4 
file 2 
whatever5 
whatever6 
file 3 
whatever7 
whatever8