包含完整字符串分隔符的提取字符串

Question

我有一个小批量脚本从mysql.err文件获取临时密码。

但我有一个问题，当一个密码包含:是在分隔符匹配使用导致密码不会得到原样..

是否有任何其他的方法来得到正确的密码？

@echo off 

setlocal enableextensions enabledelayedexpansion 

set mysql_dir=C:\database\mysql 

echo. 
echo. 
echo Search For Current MySQL Password 
FOR /F "tokens=4 delims=:" %%G in ('find /I "A temporary password is generated for root@localhost:" ^<%mysql_dir%\data\%ComputerName%.err') DO set temp_mysql_password="%%G" 

echo. 
echo. 
echo Current MySQL password: %temp_mysql_password% 

的mysql.err文件内容是：

2017-08-31T07:38:36.195916Z 0 [Warning] Gtid table is not ready to be used. Table 'mysql.gtid_executed' cannot be opened. 
2017-08-31T07:38:36.205943Z 22 [Note] A temporary password is generated for root@localhost: v>dqu;;&)7:Y 
2017-08-31T07:38:42.510215Z 0 [Warning] TIMESTAMP with implicit DEFAULT value is deprecated. Please use --explicit_defaults_for_timestamp server option (see documentation for more details). 

而问题是，密码
v>dqu;;&)7:Y **包含已:将被提取为：
v>dqu;;&)7。

Answer 1

这样无定界符它会工作：

... 
for /F "delims=" %%G in ('find /I "A temporary password is generated for" ^<%mysql_dir%\data\%ComputerName%.err') do (
    set "temp_mysql_password=%%G" 
    set "temp_mysql_password=!temp_mysql_password:*A temporary password is generated for root@localhost: =!" 
) 


echo. 
echo. 
rem Note the ! around the variable 
echo Current MySQL password: !temp_mysql_password! 

它使用说明here: Remove - Remove a substring using string substitution字符串操作。

请注意，它仅适用于root@localhost，因为该字符串是搜索替换字符串的一部分。

，使之成为任何user@host组合，你必须使用3个字符串替换，而不是一个工作：

set "temp_mysql_password=!temp_mysql_password:*A temporary password is generated for =!" 
set "temp_mysql_password=!temp_mysql_password:*@=!" 
set "temp_mysql_password=!temp_mysql_password:*: =!" 

输出：

Current MySQL password: v>dqu;;&)7:Y 

---

如果一定要使用您的解决方案（使用tokens和delims）您可以连接所有分隔的部分，请参阅here on SO how it works。

Answer 2

如果您使用过“tokens = 3 * delims =：”，而下一个变量为%% H，您将获得未解析的密码。
星号表示输入的其余部分，不用在分隔符处进一步分割。

@echo off & setlocal enableextensions enabledelayedexpansion 
set mysql_dir=C:\database\mysql 
echo. 
echo. 
echo Search For Current MySQL Password 
FOR /F "tokens=3* delims=:" %%G in (
    'find /I "A temporary password is generated for root@localhost:" ^<%mysql_dir%\data\%ComputerName%.err' 
) DO set "temp_mysql_password=%%H" 
set "temp_mysql_password=%temp_mysql_password:~1%" 
echo. 
echo. 
echo Current MySQL password: %temp_mysql_password%