如何从Smalltalk的集合中获取特定数量的随机元素？

Question

如何优雅地从集合中获取特定数量（> 1）的独特随机元素？

Answer 1

这是我觉得看起来或多或少不错的东西，但效率不高，因为它可以：

yourCollection asSet asOrderedCollection shuffled first: numberOfElements 

Answer 2

考虑下面的代码片段

sample: anInteger from: aCollection using: aGenerator 
    | sample | 
    sample := Set new: anInteger. 
    [sample size = anInteger] 
    whileFalse: [ | element | 
     element := aCollection atRandom: aGenerator. 
     sample add: element]. 
    ^sample asArray 

一些言论

• 显式生成器：它明确地使用给定的生成器，即，我称之为aGenerator的Random的实例。出于数学原因，如果您正在为您的应用程序获取样品，则所有这些应该在整个程序中使用相同的生成器。此外，这将为您带来额外的好处：保存并稍后恢复seed，您将能够重现系统的先前“随机”行为，这对测试非常有用。

• 不检查可用性：代码不检查，有可能得到期望的采样，这将是的情况下，如果aCollection不具有至少anInteger不同的元素。

• 无类代码：该方法应去一些类。

例如：

Random >> sample: anInteger from: aCollection 
    | sample | 
    sample := Set new: anInteger. 
    [sample size = anInteger] 
    whileFalse: [ | element | 
     element := aCollection atRandom: self. 
     sample add: element]. 
    ^sample asArray 

UPDATE

下面是另一种方法：

Random >> remove: anInteger from: aCollection 
    | sample | 
    sample := OrderedCollection new: anInteger. 
    anInteger timesRepeat: [| index element | 
    index := aCollection size atRandom: self. 
    element := aCollection removeAt: index. 
    sample add: element]. 
    ^sample 

评论

通常情况下，当我们想要重复采样时，我们也想从随机选取的集合中删除元素。在这些情况下，经常发生的情况是该集合已知没有重复。