动态范围内的VBA范围值

Question

我试图使范围值“粘贴”而不使用复制/粘贴功能。我对VBA相当陌生，不明白为什么我的代码不起作用。对不起，如果这是一种已经回答的问题，但我无法通过其他帖子找出问题。

我能选择我想我的价值观中复制并粘贴过与

name_task = [code].select 
name_task_2 = [code].select 

的范围，但我不能写值与

name_task_2 = name_task.value 

这工作name_task_2，对于我来说，我写了一些相同的东西，但是因为它不起作用，所以它显然不一样：D

sht2.Range("C2:D12") = sht1.Range("A8:B18").value 

Excel sheet1

Sub Time_Estimate() 

Application.ScreenUpdating = False 

Dim name_task As Variant 
Dim name_task_2 As Variant 

Dim R_count As Double 
Dim C_count As Double 

Dim sht1 As Worksheet 
Dim sht2 As Worksheet 

Set sht1 = Sheet1 'Sheets("Tekla_2016") 

name_task = sht1.Range("A8:B8", sht1.Range("A8").End(xlDown)) 
R_count = sht1.Range("A8:B8", sht1.Range("A8").End(xlDown)).Rows.Count 
'Debug.Print name_task.Rows.Count 
'Debug.Print name_task.Columns.Count 
Debug.Print R_count 

Set sht2 = Sheet2 'Sheets("Timeforbruk_2016 - UFERDIG") 

name_task_2 = sht2.Range("C2:D2", sht2.Range("C2:D2").Offset(R_count - 1, 0)) 

'name_task_2 = name_task.value 'Why doesn't this work??? 

'sht2.Range("C2:D12") = sht1.Range("A8:B18").value 'This works but it's not dynamic 


Application.ScreenUpdating = True 

End Sub 

编辑： 此代码现在的工作，因为我想：

Sub Time_Estimate() 

Application.ScreenUpdating = False 

Dim name_task As Range 
Dim name_task_2 As Range 
Dim rng_sht1 As Range 
Dim rng_sht2 As Range 


Dim R_count As Double 
Dim C_count As Double 

Dim sht1 As Worksheet 
Dim sht2 As Worksheet 

Set sht1 = Sheet1 'Sheets("Tekla_2016") 
Set sht2 = Sheet2 'Sheets("Timeforbruk_2016 - UFERDIG") 

Set name_task = sht1.Range("A8:B8", sht1.Range("A8").End(xlDown)) 
R_count = sht1.Range("A8:B8", sht1.Range("A8").End(xlDown)).Rows.Count 

Set name_task_2 = sht2.Range("C2:D2", sht2.Range("C2:D2").Offset(R_count - 1, 0)) 
name_task_2 = name_task.value 

Application.ScreenUpdating = True 

End Sub 

Answer 1

someRange.Select 

选择范围someRange并返回布尔值True（你通常不会注意到，因为你不要试图将它分配给某些东西）。这意味着，后

name_task = [code].select 
name_task_2 = [code].select 

既name_task和name_task_2是布尔值（True），而不是范围。

在你发布你的子有另一个问题：

name_task = sht1.Range("A8:B8", sht1.Range("A8").End(xlDown)) 

因为你没有指定name_task是（除Variant，这基本上意味着什么）什么，VBA将使用范围的Value为默认属性和name_task将是包含sht1.Range("A8:B8", sht1.Range("A8").End(xlDown)).Value的变体阵列。要指定一个范围对象你需要使用Set：

Set name_task = sht1.Range("A8:B8", sht1.Range("A8").End(xlDown)) 

从MSDN/this answer：

设定关键字。在VBA中，Set关键字对于区分对象的分配和对象的默认属性的分配是必要的。由于Visual Basic .NET不支持默认属性，因此不需要Set关键字，因此不再支持。

这实际上是一个很好的例子，为什么使用Option Explicit（或者在你的情况下正确地声明变量）是一个好主意。如果您声明Dim name_task As Range VBA会告诉您在正确的线路上出现问题，故障排除变得更加容易。