如何从数组中减去数组？

Question

当我尝试以下方法

#!/usr/bin/perl 

use strict; 
use warnings; 
use Data::Dumper; 

my @bl = qw(red green blue); 
my @a = qw(green yellow purple blue pink); 

print Dumper [grep {not @bl} @a]; 

我得到一个空数组。我预料@bl从@a减去，所以输出是yellow purple pink。

这里有什么问题？

Answer 1

您需要打开@bl到一个哈希执行差集：

my %in_bl = map {$_ => 1} @bl; 
my @diff = grep {not $in_bl{$_}} @a; 

Answer 2

见perlfaq4: How do I compute the difference of two arrays?

在你的代码，not很可能无法做你觉得它在做什么。

not @bl将总是1如果@bl为空数组，和undef如果@bl不为空。 从任何意义上说，这并不意味着“元素不在@bl”。

Answer 3

@b1计算结果为真（这是一个非零数字元素的数组），因此布尔测试你的grep构造（not @b1）将始终返回false。 grep过滤仅返回布尔测试返回true的元素的数组。

您需要测试以确定$_（当前正在考虑的数组元素）是否在@bl之内。要做到这一点的方法之一是使用@bl作为键，然后在grep的声明支票的$_在哈希键的存在，产生一个临时散：

#!/usr/bin/perl 

use strict; 
use warnings; 
use Data::Dumper; 

my @bl = qw(red green blue); 
my @a = qw(green yellow purple blue pink); 

# create a hash 
my %h; 

# nifty trick - use a hash slice to populate the 
# hash. The values are irrelevant so we'll use @bl 
# for those too 
@h{@bl} = @bl; 

print Dumper [grep {!exists $h{$_}} @a]; 

Answer 4

的另一种方法，使用minus功能从Acme::Tools CPAN模块：

use strict; 
use warnings; 
use Data::Dumper; 
use Acme::Tools qw(minus); 

my @bl = qw(red green blue); 
my @a = qw(green yellow purple blue pink); 
my @diff = minus(\@a, \@bl); 
print Dumper(\@diff); 

__END__ 

$VAR1 = [ 
      'yellow', 
      'purple', 
      'pink' 
     ]; 

Answer 5

另一种选择使用perl5i：

use perl5i::2; 

my @bl = qw(red green blue); 
my @a = qw(green yellow purple blue pink); 
my @diff = @a->diff(\@bl); 

say @diff->mo->perl; 

Answer 6

由于Perl 5.18.0，smartmatch运算符被认为是实验性的： The smartmatch family of features are now experimental。 因此，我不会再使用下面的解决方案。

与Smartmatch运营商的另一种方式（如果你有Perl版本5.010或更高）：

#!/usr/bin/env perl 
use warnings; 
use 5.012; 

my @bl = qw(red green blue); 
my @a = qw(green yellow purple blue pink); 

my @s = grep{ not $_ ~~ @bl } @a; 
say "@s"; # yellow purple pink 

Answer 7

另一种方法是使用：

List::Compare CPAN module 
use List::Compare ; 
... 
my $compare_obj 
    = List::Compare->new(\@a , \@b1) ; 
@diff = $compare_obj->get_Lonly() ; 
...