Automator/Applescript文件排序和移动

我想知道在Automator中是否有方法使用Applescript代码来获取文件的扩展名，并且如果它等于特定的扩展名（例如.pdf或.rtf）移动到特定的文件夹对于该扩展（例如if (extension == pdf) { move to folder "~/PDF Files" } else if (extension == rtf) { move to folder "~/Rich Text Files" }）Automator/Applescript文件排序和移动

来源

2010-07-28 Hank Brekke

这是一个applescript。既然你的要求很简单，我就为你写了。请注意我如何使用子例程“getNameAndExtension（F）”获取文件扩展名。通常情况下，您可以从Finder获得文件扩展名（称为扩展名），但我发现Finder并不总是可靠的，所以我总是使用该子例程。该子程序一直可靠。

set homeFolder to path to home folder as text 
set rtfFolderName to "Rich Text Files" 
set pdfFolderName to "PDF Files" 

-- choose the files 
set theFiles to choose file with prompt "Choose RTF or PDF files to move into your home folder" with multiple selections allowed 

-- make sure the folders exist 
tell application "Finder" 
    if not (exists folder (homeFolder & rtfFolderName)) then 
     make new folder at folder homeFolder with properties {name:rtfFolderName} 
    end if 
    if not (exists folder (homeFolder & pdfFolderName)) then 
     make new folder at folder homeFolder with properties {name:pdfFolderName} 
    end if 
end tell 

-- move the files 
repeat with aFile in theFiles 
    set fileExtension to item 2 of getNameAndExtension(aFile) 
    if fileExtension is "rtf" then 
     tell application "Finder" 
      move aFile to folder (homeFolder & rtfFolderName) 
     end tell 
    else if fileExtension is "pdf" then 
     tell application "Finder" 
      move aFile to folder (homeFolder & pdfFolderName) 
     end tell 
    end if 
end repeat 



(*=============== SUBROUTINES ===============*) 
on getNameAndExtension(F) 
    set F to F as Unicode text 
    set {name:Nm, name extension:Ex} to info for file F without size 
    if Ex is missing value then set Ex to "" 
    if Ex is not "" then 
     set Nm to text 1 thru ((count Nm) - (count Ex) - 1) of Nm 
    end if 
    return {Nm, Ex} 
end getNameAndExtension

来源

2010-07-29 12:30:41 regulus6633

我现在不在我的苹果，所以我不能玩Automator和弄清楚。但是，如果您可以通过将查找器切换到列表视图来执行此操作，请按类型进行排序，然后选择相同类型的文件块并将它们拖到正确的文件夹中。

来源

2010-07-28 18:16:58 Nathan

Automator/Applescript文件排序和移动

回答

相关问题