范围链接到最后一个单元格在相邻的列

Question

我有一个工作表，有4列，我写了一个宏来将公式放在A + B列中，这些列依赖于D列中的内容，然后将其作为值复制并粘贴到启用这些列的过滤。我的问题是，每周的列D变得更长。我不希望要不断改变我的宏的值A + B（A2：A69422）的范围，其中69422是列在最后使用的细胞D.

Worksheets("salesinfo").Range("B2").Formula = "= MID(D3,3,5)" 
    Range("B2").Select 
     Selection.AutoFill Destination:=Range("B2:B69422") 
     Range("B2:B69422").Select 
     Selection.Copy 
     Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _ 
      :=False, Transpose:=False 

    Selection.Value = Selection.Value 

    Range("A2").Formula = "= VLOOKUP(B2,[Data.xlsb]Stores!$A:$X,4,0)" 

    Range("A2").Select 
     Selection.AutoFill Destination:=Range("A2:A69422") 
     Range("A2:A69422").Select 
     Selection.Copy 
     Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _ 
      :=False, Transpose:=False 

      Workbooks("Data.xlsb").Close SaveChanges:=False 

      Application.CutCopyMode = False 

      Range("A2").Select 

Answer 1

使用以下语法确定列D中的最后一行，然后将其分配给变量Long或Integer变量。在我的例子我使用lRow作为我的变量：

Dim lRow As Long 

With ActiveSheet 

    lRow = .Cells(.Rows.Count, 4).End(xlUp).Row 

End With 

然后，只需在单元格地址的行引用使用lRow + 1。

Answer 2

如TheGuyThatDoesn'tKnowMuch所述，声明一个Long类型变量并存储模式相关列的最后一个已填充行最好通过从下往上查看来完成。这相当于从工作表底部开始并点击Ctrl + ▲。

以下是一些可以改进代码的其他方法。

• 定义你Workbook Object和Worksheet Object与With ... End With statement，并通过与.像.Range(...)前缀每个Range object使用该引用。请勿将.Parent工作表引用隐含;总是让他们明确。
• 一次写下所有的公式;无需使用Range.AutoFill method。
• 直接值转移比复制&选择性粘贴特殊值更有效，并且不涉及剪贴板。
• 避免使用Range.Select和Range.Activate方法¹。他们可能是开始使用VBA的好方法，但他们也是您应该毕业的第一件事。
  

引用列A：外部工作簿中的X在VLOOKUP function内，当您只需要A：D时效率低下;在任何情况下，一个INDEX/MATCH函数对可能对于大量的行更好。

您正在向列A中写入一个引用外部工作簿Data.xlsb的公式，因此我知道这不是包含salesinfo工作表的工作表。您应该调整下面的工作簿参考以避免使用ActiveWorkbook property。

Dim lr As Long 

    With ActiveWorkbook 
     With .Worksheets("salesinfo") 
      lr = .Cells(.Rows.Count, "D").End(xlUp).Row 
      With .Range("B2:B" & lr) 
       .Formula = "=MID(D3, 3, 5)" 
       .Value = .Value 
      End With 
      With .Range("A2:A" & lr) 
       .Formula = "=VLOOKUP(B2, [Data.xlsb]Stores!$A:$X, 4, FALSE)" 
       'alternate formula 
       '.Formula = "=INDEX([Data.xlsb]Stores!$D:$D, MATCH(B2, [Data.xlsb]Stores!$A:$A, 0))" 
       .Value = .Value 
      End With 
      .Range("A2").Activate 
     End With 
    End With 

    Workbooks("Data.xlsb").Close SaveChanges:=False 

针对列B的公式涉及到我一点。您正在使用B2中的公式引用D3。这意味着如果公式在列B中填充以匹配列D中的所有值，则最后公式实际上将引用列D中最后一个填充单元格下方的空白单元格。

如果遇到计算滞后问题（花费太长时间）将两列公式写入近70K行，字典对象和变体数组可能会非常明显地加快速度。

---

.¹_{见How to avoid using Select in Excel VBA macros更多的方法从依靠选择越来越远，并激活，以实现自己的目标。}