如何跳过嵌套块中的异常

Question

我的程序中有2个嵌套块。如果在第一个嵌套块中发生任何错误，那么程序将不会继续执行，它将转到异常部分并退出整个程序。 但我不想退出我的计划。我的程序需要为第二个嵌套块执行，而且，即使在第一个嵌套块中引发异常。

如果我有这样的程序：

DECLARE 
    var_out VARCHAR2(10):= 'OUTER'; 
BEGIN 
    <<INNER1>> 
    DECLARE 
     var_in1 NUMBER:='INNER 1'; 
    BEGIN 
     DBMS_OUTPUT.PUT_LINE(var_in1); 
    EXCEPTION 
     WHEN OTHERS THEN 
      DBMS_OUTPUT.PUT_LINE(SQLERRM); 
    END; 

    <<INNER2>> 
    DECLARE 
     var_in2 VARCHAR2(10):='INNER 2'; 
    BEGIN 
     DBMS_OUTPUT.PUT_LINE(var_in2); 
    EXCEPTION 
     WHEN OTHERS THEN 
      DBMS_OUTPUT.PUT_LINE(SQLERRM); 
    END; 
    DBMS_OUTPUT.PUT_LINE(var_out); 
EXCEPTION 
    WHEN OTHERS THEN 
     DBMS_OUTPUT.PUT_LINE(SQLERRM); 
END; 

在我的计划inner1块

将抛出value error exception所以总体方案将不被执行。

如何执行inner2和outer block，甚至在inner1块中引发异常？

Answer 1

由于INNER1中的异常发生在声明部分内，因此超出了该块的异常处理程序的范围。您需要用其自己的异常处理程序将整个INNER1块包装到另一个块中。

declare 
    var_out varchar2(10):= 'OUTER'; 
begin 
    <<INNER1>> 
    begin 
     declare 
      var_in1 number:='INNER 1'; 
     begin 
      dbms_output.put_line(var_in1); 
     exception 
      when others then 
       dbms_output.put_line('Error in innermost INNER1'); 
     end; 
    exception 
     when others then 
      dbms_output.put_line('Error in INNER1 wrapper'); 
    end; 

    <<INNER2>> 
    declare 
     var_in2 varchar2(10):='INNER 2'; 
    begin 
     dbms_output.put_line(var_in2); 
    exception 
     when others then 
      dbms_output.put_line('Error in INNER2'); 
    end; 
    dbms_output.put_line(var_out); 
exception 
    when others then 
     dbms_output.put_line('Error at top level'); 
end; 

输出：可能不需要

Error in INNER1 wrapper 
INNER 2 
OUTER 

既OTHERS搬运车 - 上面的仅仅是为了说明的结构。