秒表循环使用VB.NET

Question

我想创建一个简单的定时器使用VB.NET

我想按Button1的，并开始在文本框中秒计数，这个接口。

I do not want to use the Timer Component because it does not offer high resolution.

所以，我按规格决定使用秒表类，由于其较高的分辨率。

但根据我的VB.NET代码，在我看来，整个“dotnet冒险”是不可能的。这是因为当我按下Button1时，整个窗体冻结，我不能按Button2来停止计时器。

我的代码有什么问题吗？ 我应该怎么做才能具备上述功能？

在此先感谢！

 
Public Class Form1
 

Private enableTime As TimeSpan 
Private stopWatch As New Stopwatch() 

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click 
    stopWatch.Start() 
    If stopWatch.IsHighResolution Then 
     Do 
      If stopWatch.ElapsedTicks.Equals(TimeSpan.TicksPerSecond) Then 
       enableTime = enableTime + TimeSpan.FromSeconds(1) 
       TextBox1.Text = enableTime.ToString 
       stopWatch.Restart() 
      End If 
      If Not stopWatch.IsRunning Then 
       Exit Do 
      End If 
     Loop 
    End If 
End Sub 

Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click 
    stopWatch.Stop() 
    stopWatch.Reset() 
End Sub 

末级

Answer 1

Winforms中，有执行所述消息循环一个UI线程。基本上，每个事件都会被添加到消息队列中，并被处理，一个接一个的事件。当单击Button1时，将执行Button1_Click方法，直到完成后才会处理其他事件。由于您的设计需要处理Button2.Click以终止Button1.Click中的循环，因此它不会终止。

要正确实现你想要的，你必须在Button1.Click上启动秒表，并将UI更新逻辑放入您放置在窗体上的计时器的Tick事件中。

Answer 2

由于您正在手动添加时间范围，因此您“失去”时间：enableTime = enableTime + TimeSpan.FromSeconds(1)。秒表（）本身始终准确，当您使用其Stopwatch.Elapsed属性。您只需从Timer.Tick事件更新GUI即可。基本上，计时器只是询问秒表什么是当前时间，并显示它......不需要计算。

下面将更新的第二十次，不会“漂移”，并且将不钉住CPU：

Public Class Form1 

    Private SW As New Stopwatch 
    Private WithEvents Tmr As New System.Windows.Forms.Timer 

    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load 
     Tmr.Interval = 100 
    End Sub 

    Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click 
     SW.Start() 
     Tmr.Start() 
    End Sub 

    Private Sub Tmr_Tick(sender As Object, e As System.EventArgs) Handles Tmr.Tick 
     TextBox1.Text = SW.Elapsed.ToString 
    End Sub 

    Private Sub Button2_Click(sender As System.Object, e As System.EventArgs) Handles Button2.Click 
     SW.Stop() 
     Tmr.Stop() 
     SW.Reset() 
    End Sub 

End Class 

Answer 3

一个实验表明，计时器不应该被用于定时。使用计时器定期显示秒表经过时间是很好的。

Public Class Form1 
    Private stpw As New Stopwatch 
    Private WithEvents aTimer As New System.Windows.Forms.Timer 

    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load 
     aTimer.Interval = 100 'ten times per second 
     aTimer.Start() 'start the timer 
    End Sub 

    Private Sub timeTick(sender As Object, e As System.EventArgs) Handles aTimer.Tick 
     If stpw.IsRunning Then 
      'show that using the timer tick is not accurate for timing 
      'add the number of ms. to the timespan 
      'if the tick occurs exactly on the interval this will be accurate 

      elapsedTM = elapsedTM.Add(New TimeSpan(0, 0, 0, 0, aTimer.Interval)) 

      'show the two elapsed times 
      'as of .Net 4.0 format elapsed 
      TextBox1.Text = stpw.Elapsed.ToString("hh\:mm\:ss\.f") 
      TextBox2.Text = elapsedTM.ToString("hh\:mm\:ss\.f") 

      'show the time according to the system 
      TextBox3.Text = DateTime.Now.ToString("hh:mm:ss.f") 
      'show the time by adding the start time and the stopwatch elapsed time 
      TextBox4.Text = strt.AddMilliseconds(stpw.ElapsedMilliseconds).ToString("hh:mm:ss.f") 
     End If 
    End Sub 

    Dim strt As DateTime 
    Dim elapsedTM As TimeSpan 

    Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click 
     'start 
     If Not stpw.IsRunning Then 
      elapsedTM = New TimeSpan(0L) 
      'record the start time 
      strt = DateTime.Now 
      stpw.Start() 'start the stopwatch 
      Button2.Select() 
     End If 
    End Sub 

    Private Sub Button2_Click(sender As System.Object, e As System.EventArgs) Handles Button2.Click 
     'stop 
     stpw.Stop() 
     stpw.Reset() 
     Button1.Select() 
    End Sub 
End Class