xslt计算保险注销不起作用

Question

我正试图计算医疗保险的合同核销，但计算似乎没有工作。例如，我需要取<charge>标签上的费用属性值，然后减去<adjustment>标签上的金额属性值，但仅当<adjustment>标签上的组和代码属性为：group ='CO'和代码='45'或'385'

我能够得到一切，但计算工作。我试着在这个论坛上看到几个答案，但我明显错过了一些东西。任何帮助，将不胜感激。

这里是我的XML（简体）：

<result check_number="05173408" ...> 
    <claim ... total_charge="720" total_paid="43"> 
     <charge charge="200"> 
      <adjustment amount="125" code="45" group="CO" /> 
      <adjustment amount="35" code="385" group="CO" /> 
      <adjustment amount="20" code="3" group="PR" /> 
     </charge> 
     <charge charge="70"> 
      <adjustment amount="70" code="204" group="PR" /> 
     </charge> 
     <charge charge="300"> 
      <adjustment amount="273" code="45" group="CO" /> 
      <adjustment amount="15" code="3" group="PR" /> 
     </charge> 
     <charge charge="150"> 
      <adjustment amount="139" code="45" group="CO" /> 
     </charge> 
    </claim> 
</result> 

这里是我的XSLT把日期：

<?xml version="1.0" encoding="UTF-8" ?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" exclude-result-prefixes="xsl"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" /> 
    <xsl:template match="/"> 
     <!-- maps to the beginning result tag --> 
     <xsl:for-each select="/result/claim/charge"> 
     <!-- amount allowed by the insurance for line item --> 
      <COL> 
       <DATA> 
       <xsl:apply-templates select="adjustment" mode="calcAdjTotal" > 
       </xsl:apply-templates> 
       </DATA> 
      </COL> 
     </xsl:for-each> 
     <!-- Template created to test Parfait's suggestion --> 
     <xsl:template match="adjustment" mode="calcAdjTotal" > 
      <xsl:variable name="condition" select="adjustment[@group='CO' and (@code='45' or @code='385')]"></xsl:variable> 
       <xsl:value-of select="../@charge - sum($condition/@amount)" /> 
      </xsl:if> 
     </xsl:template> 
    </xsl:template> 
</xsl:stylesheet> 

这里是我的输出：（更新输出）

<COL> 
    </DATA> 
</COL> 
<COL> 
    </DATA> 
</COL> 
<COL> 
    </DATA> 
</COL> 
<COL> 
    </DATA> 
</COL> 

这里的我想要得到的：

<COL> 
    <DATA> 
     40 
    </DATA> 
</COL> 
<COL> 
    <DATA> 
    </DATA> 
</COL> 
<COL> 
    <DATA> 
     27 
    </DATA> 
</COL> 
<COL> 
    <DATA> 
     11 
    </DATA> 
</COL> 

然后将使用该格式将数据导入Filemaker。

Answer 1

考虑将您的条件方程包装在<xsl:if>中。此外，您可以使用一个存储条件值的变量来避免重复：

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 
<xsl:output version="1.0" encoding="UTF-8" indent="yes" /> 
<xsl:strip-space elements="*"/>  

    <xsl:template match="/"> 
    <ROOT> 
     <xsl:apply-templates select="*"/> 
    </ROOT> 
    </xsl:template> 

    <xsl:template match="charge"> 
    <xsl:variable name="condition" select="adjustment[(@code='45' or @code='385') and @group='CO']"/>   
    <COL> 
     <DATA> 
     <xsl:if test="$condition">    
      <xsl:value-of select="@charge - sum($condition/@amount)"/>    
     </xsl:if> 
     </DATA> 
    </COL>  
    </xsl:template>  
</xsl:transform> 

Answer 2

我猜你想要的东西，像（！）：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 

<xsl:template match="/result"> 
    <RESULT> 
     <xsl:for-each select="claim/charge"> 
      <ROW> 
       <COL> 
        <DATA> 
         <xsl:value-of select="@charge - sum(adjustment[@group='CO' and (@code='45' or @code='385')]/@amount)" /> 
        </DATA> 
       </COL> 
      </ROW> 
     </xsl:for-each> 
    </RESULT> 
</xsl:template> 

</xsl:stylesheet> 

应用到你的输入例子，结果将是：

<?xml version="1.0" encoding="UTF-8"?> 
<RESULT> 
    <ROW> 
     <COL> 
     <DATA>40</DATA> 
     </COL> 
    </ROW> 
    <ROW> 
     <COL> 
     <DATA>70</DATA> 
     </COL> 
    </ROW> 
    <ROW> 
     <COL> 
     <DATA>27</DATA> 
     </COL> 
    </ROW> 
    <ROW> 
     <COL> 
     <DATA>11</DATA> 
     </COL> 
    </ROW> 
</RESULT> 

这是假设你想为每个charge创建一个记录（有一个字段）。

请注意，这是无效的FileMaker XML语法。

---

- 响应编辑，以澄清在评论： -

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 

<xsl:template match="/result"> 
    <RESULT> 
     <xsl:for-each select="claim/charge[adjustment[not(@group='PR')]]"> 
      <ROW> 
       <COL> 
        <DATA> 
         <xsl:value-of select="@charge - sum(adjustment[not(@group='PR')]/@amount)" /> 
        </DATA> 
       </COL> 
      </ROW> 
     </xsl:for-each> 
    </RESULT> 
</xsl:template> 

</xsl:stylesheet> 

结果

<?xml version="1.0" encoding="UTF-8"?> 
<RESULT> 
    <ROW> 
     <COL> 
     <DATA>40</DATA> 
     </COL> 
    </ROW> 
    <ROW> 
     <COL> 
     <DATA>27</DATA> 
     </COL> 
    </ROW> 
    <ROW> 
     <COL> 
     <DATA>11</DATA> 
     </COL> 
    </ROW> 
</RESULT>