sys_execve系统调用

Question

asm_execve.s：

 
.section .data 
file_to_run: 
.ascii  "/bin/sh" 

.section .text 
.globl main 

main: 
    pushl %ebp 
    movl %esp, %ebp 
    subl $0x8, %esp   # array of two pointers. array[0] = file_to_run array[1] = 0 

    movl file_to_run, %edi 
    movl %edi, -0x4(%ebp) 
    movl $0, -0x8(%ebp) 

    movl $11, %eax      # sys_execve 
    movl file_to_run, %ebx    # file to execute  
    leal -4(%ebp), %ecx     # command line parameters 
    movl $0, %edx      # environment block 
    int $0x80    

    leave 
    ret 

生成文件：

 
NAME = asm_execve 
$(NAME) : $(NAME).s 
    gcc -o $(NAME) $(NAME).s 

程序被执行，但sys_execve不叫：

 
alex@alex32:~/project$ make 
gcc -o asm_execve asm_execve.s 
alex@alex32:~/project$ ./asm_execve 
alex@alex32:~/project$ 

预期成果是：

 
alex@alex32:~/project$ ./asm_execve 
$ exit 
alex@alex32:~/project$ 

本届大会的程序应该像下面的C代码工作：

 
char *data[2]; 
data[0] = "/bin/sh"; 
data[1] = NULL; 
execve(data[0], data, NULL); 

一些错误的系统调用的参数？

Answer 1

execve系统调用是被调用，但你的确在传递它坏的参数。

（您可以通过使用strace运行可执行文件看到这一点。）

有三个问题：

1. .ascii没有0结束的字符串。 （您可能会很幸运，因为在本例中您的.data部分没有任何内容，但不能保证......）添加0或使用.asciz（或.string）代替。

2. movl file_to_run, %edi移动指向由file_to_run符号到%edi值，即第一个4个字节串（0x6e69622f）的。该字符串的地址只是该符号本身的值，因此您需要使用$前缀的文字值：movl $file_to_run, %edi。同样，你需要在下面说几句movl $file_to_run, %ebx。 （这是AT & T语法和Intel语法之间的混淆的常见来源！）

3. 的参数被放置在错误的顺序在堆栈上：-0x8(%ebp)比-0x4(%ebp)低位地址。所以命令字符串的地址应该写入-0x8(%ebp)，0应该写入-0x4(%ebp)，并且leal指令应该是leal -8(%ebp), %ecx。

---

固定码：

.section .data 
file_to_run: 
.asciz  "/bin/sh" 

.section .text 
.globl main 

main: 
    pushl %ebp 
    movl %esp, %ebp 
    subl $0x8, %esp   # array of two pointers. array[0] = file_to_run array[1] = 0 

    movl $file_to_run, %edi 
    movl %edi, -0x8(%ebp) 
    movl $0, -0x4(%ebp) 

    movl $11, %eax      # sys_execve 
    movl $file_to_run, %ebx    # file to execute  
    leal -8(%ebp), %ecx     # command line parameters 
    movl $0, %edx      # environment block 
    int $0x80    

    leave 
    ret 

Answer 2

你其实并不需要在其他参数加载任何东西。如果你在86做这下面简单的代码也将工作：

.global _main 
.section .text 

.data 
file_to_run: 
.asciz "/bin/sh" 

.section .text 
.globl main 

_main: 
pushl %ebp 
movl %esp, %ebp 

movl $11, %eax      # sys_execve 
movl $file_to_run, %ebx    # file to execute  
movl $0, %ecx      # Null value will work too 
movl $0, %edx      # Null will works too 
int $0x80    

leave 
ret 

调用系统调用后，这将从根本上打开一个shell终端。