Perl的IPv6地址扩展/解析

Question

我有一个地址像标量2001:db8::1，并希望得到扩展形式，2001:0db8:0000:0000:0000:0000:0000:0001。主要的Perl软件包是否在/usr/lib/perl5/...这个庞大的森林里 - 这个模块已经可以做到这一点了？如果没有，是否有人会做几行呢？

Answer 1

CPAN有Net::IP它可以做你所需要的。

这里有一个成绩单您展示它在行动：

$ cat qq.pl 
use Net::IP; 
$ip = new Net::IP ('2001:db8::1'); 
print $ip->ip() . "\n"; 

$ perl qq.pl 
2001:0db8:0000:0000:0000:0000:0000:0001 

Answer 2

Net::IP绝对是一个伟大的路要走，因为它很容易和强大。但是，如果要分析大量的对象，则可以考虑使用Socket包中的inet_pton，因为它比Net::IP对象版本快10-20倍，即使对象是预创建的也是如此。 ，比ip_expand_address版本快4ish时间：

use Net::IP; 
use Time::HiRes qw(gettimeofday tv_interval); 
use Socket qw(inet_pton AF_INET6); 
use bignum; 
use strict; 

# bootstrap 
my $addr = "2001:db8::1"; 
my $maxcount = 10000; 

my $ip = new Net::IP($addr); 

my ($t0, $t1); 
my $res; 

# test Net::IP 
$t0 = [gettimeofday()]; 
for (my $i = 0; $i < $maxcount; $i++) { 
    $ip->set($addr); 
    $res = $ip->ip(); 
} 
print "Net::IP elapsed: " . tv_interval($t0) . "\n"; 
print "Net::IP Result: $res\n"; 

# test non-object version 
$t0 = [gettimeofday()]; 
for (my $i = 0; $i < $maxcount; $i++) { 
    $res = Net::IP::ip_expand_address('2001:db8::1', 6); 
} 
print "ip_expand elapsed: " . tv_interval($t0) . "\n"; 
print "ip_expand Result: $res\n"; 

# test inet_pton 
$t0 = [gettimeofday()]; 
for (my $i = 0; $i < $maxcount; $i++) { 
    $res = join(":", unpack("H4H4H4H4H4H4H4H4",inet_pton(AF_INET6, $addr))); 
} 
print "inet_pton elapsed: " . tv_interval($t0) . "\n"; 
print "inet_pton result: " . $res . "\n"; 

随机机器上运行本作制作我：

Net::IP elapsed: 2.059268 
Net::IP Result: 2001:0db8:0000:0000:0000:0000:0000:0001 
ip_expand elapsed: 0.482405 
ip_expand Result: 2001:0db8:0000:0000:0000:0000:0000:0001 
inet_pton elapsed: 0.132578 
inet_pton result: 2001:0db8:0000:0000:0000:0000:0000:0001