将用户名转换为WindowsIdentity？

Question

我已经标记了这个问题与C#因为是.NET一部分，众所周知，有些人可以编程，没有问题了解双方VB.NET和C#为一体，我不应该有问题，翻译C#指令VB.NET然后我会对用这些语言之一编写的解决方案感到满意。

---

我想在此功能指定的用户名来检索，如果它是一个管理员或没有什么变化，我应该怎么办？

MsgBox(UserIsAdmin("Elektro")) 

' ByVal UserName as String or other needed object. 
Public Function UserIsAdmin(ByVal UserName As XXXX) As Boolean 

    Dim Identity As Security.Principal.WindowsIdentity = 
    Security.Principal.WindowsIdentity.FromUserName(UserName) 

    Return New Security.Principal.WindowsPrincipal(Identity). 
       IsInRole(Security.Principal.WindowsBuiltInRole.Administrator) 

End Function 

PS：当然FromUserName方法不存在。

---

UPDATE

我只是想@meziantou的方法，但我总是对用户名结构或有关网络条目中找不到一个例外，但是，不管怎么说，这不是确切地说我在找什么（我的意思是指定一个域或computername或其他任何不是由函数自动完成的）。

Public Class Form 

Private Sub Test() Handles MyBase.Shown 

    ' Things that I've tried: 

    MsgBox(UserIsAdmin("Administrador")) ' Username 
    MsgBox(UserIsAdmin("Administrador@127.0.0.1")) ' Username@LocalHost 
    MsgBox(UserIsAdmin(Security.Principal.WindowsIdentity.GetCurrent().Name)) ' DomainName\Username 
    MsgBox(UserIsAdmin("Administrador@ELEKTRO")) ' Username@DomainName 
    MsgBox(UserIsAdmin(Security.Principal.WindowsIdentity.GetCurrent.User.Value)) ' The SID 

End Sub 

''' <summary> 
''' Determines whether an user is an Administrator. 
''' </summary> 
''' <returns><c>true</c> if the user is an Administrator, <c>false</c> otherwise.</returns> 
Public Function UserIsAdmin(Optional ByVal UserName As String = String.Empty) As Boolean 

    Dim Identity As Security.Principal.WindowsIdentity = 
     If(Not String.IsNullOrEmpty(UserName), 
      New Security.Principal.WindowsIdentity(UserName), 
      Security.Principal.WindowsIdentity.GetCurrent()) 

    Return New Security.Principal.WindowsPrincipal(Identity). 
       IsInRole(Security.Principal.WindowsBuiltInRole.Administrator) 

End Function 

End Class 

---

更新2

我尝试@Frinavale的做法，但我不能够适应这个代码来检索我感兴趣的信息。

Imports System.DirectoryServices.AccountManagement 
Imports System.Security.Principal 

Public Class Form1 

    Private Sub Test() Handles MyBase.Shown 

     Dim pContext As PrincipalContext = New PrincipalContext(ContextType.Machine) 
     Dim pUsers As Principal = New UserPrincipal(pContext) 
     Dim pSearcher As PrincipalSearcher = New PrincipalSearcher(pUsers) 

     For Each User As Principal In pSearcher.FindAll() 

      For Each Group As Principal In User.GetGroups 
       ' Result of 'Administrators' (in Spanish): 'Administradores', 
       ' so this is not efficient to compare. 
       MsgBox(Group.Name) 
      Next 

      ' Any of these works: 
      ' It throws an exception because 
      ' i'm not passing the expected parameter for a WindowsIdentity. 

      MsgBox(UserIsAdmin(User.Name)) 
      ' MsgBox(UserIsAdmin(User.UserPrincipalName)) 
      ' MsgBox(UserIsAdmin(User.DistinguishedName)) 
      ' MsgBox(UserIsAdmin(User.SamAccountName)) 

     Next User 

    End Sub 

    Public Function UserIsAdmin(ByVal User As String) As Boolean 

     Using Identity As New WindowsIdentity(User) 
      Return New WindowsPrincipal(Identity).IsInRole(WindowsBuiltInRole.Administrator) 
     End Using 

    End Function 

End Class 

Answer 1

可以使用GroupPrincipal Class检索是管理员组的一部分的所有用户。拥有所有成员后，您可以通过将成员的名称与提供的用户名进行比较来确定用户是否在组中。

例如：

Public Function UserIsAdmin(ByVal userName As String) As Boolean 
     Dim groupName As String = "administrators" '<--You can localize this' 
     Dim isAdmin As Boolean 
     Using context As PrincipalContext = New PrincipalContext(ContextType.Machine) 
      Dim gfilter As GroupPrincipal = GroupPrincipal.FindByIdentity(context, groupName) 
      If gfilter IsNot Nothing Then 
       Dim members = gfilter.GetMembers 
       For Each member In members 
        If String.Compare(member.Name, userName, True) = 0 Then 
         isAdmin = True 
        End If 
       Next 
      End If 
     End Using 
     Return isAdmin 
End Function 

我知道你提到，该集团的名称是局部的（因为我使用的是美国英语操作系统/环境未发生对我来说）。在这种情况下，我建议您查看Globalization（将“管理员”的本地化版本存储到资源文件中，密钥为“管理员”，然后根据您所在的文化检索“管理员”的相应文本工作中）

Answer 2

为了得到一个用户名的WindowsIdentity，则可以使用WindowsIdentity构造（http://msdn.microsoft.com/en-us/library/td3046fc(v=vs.110).aspx）

Dim windowsIdentity = New WindowsIdentity("administrator") 
New WindowsPrincipal(windowsIdentity).IsInRole(WindowsBuiltInRole.Administrator) 

Answer 3

MSDN说，一个WindowsIdentity对象也只能是登录的用户，所以似乎是不可能做到这一点，我想用户名的转换，但是，这是一个有效的解决方案：

' User Is Admin? 
' 
' Instructions: 
' 1. Add a reference to 'System.DirectoryServices.AccountManagement'. 
' 2. Imports System.DirectoryServices.AccountManagement 
' 
' Example Usages: 
' MsgBox(UserIsAdmin("Administrador")) 
' MsgBox(UserIsAdmin(New Security.Principal.SecurityIdentifier("S-1-5-21-250596608-219436059-1115792336-500"))) 
' 
''' <summary> 
''' Determines whether an User is an Administrator, in the current machine. 
''' </summary> 
''' <param name="UserName">Indicates the account Username.</param> 
''' <returns><c>true</c> if user is an Administrator, <c>false</c> otherwise.</returns> 
Public Function UserIsAdmin(ByVal UserName As String) As Boolean 

    Dim AdminGroupSID As New SecurityIdentifier("S-1-5-32-544") 

    Dim pContext As New PrincipalContext(ContextType.Machine) 
    Dim pUser As New UserPrincipal(pContext) 
    Dim pSearcher As New PrincipalSearcher(pUser) 

    Dim User As Principal = 
     (From u As Principal In pSearcher.FindAll 
     Where u.Name.Equals(UserName, StringComparison.OrdinalIgnoreCase)).FirstOrDefault 

    If User Is Nothing Then 
     Throw New Exception(String.Format("User with name '{0}' not found.", UserName)) 
    End If 

    Dim IsAdmin As Boolean = 
     (From Group As GroupPrincipal In User.GetGroups 
     Where Group.Sid = AdminGroupSID).Any 

    pContext.Dispose() 
    pSearcher.Dispose() 
    pUser.Dispose() 

    Return IsAdmin 

End Function