单击已打开的浏览器窗口中的href链接

Question

在下面的代码中，我尝试单击www.google.co.in网站上的“关于”链接（href）。这适用于IE11（Windows 10），但不适用于IE10（Windows 7）。这是否依赖于机器。如果不是什么是正确的代码？

请记住我试图点击已打开的浏览器窗口中的链接。

Set objShell = CreateObject("Shell.Application") 
IE_count = objShell.Windows.Count 
For x = 0 To (IE_count - 1) 
    On Error Resume Next ' sometimes more web pages are counted than are open 
    my_url = objShell.Windows(x).Document.Location 
    my_title = objShell.Windows(x).Document.Title 

    'You can use my_title of my_url, whichever you want 
    If my_title Like "Google" & "*" Then 'identify the existing web page 
     Set ie = objShell.Windows(x) 
     Exit For 
    Else 
    End If 
Next 

Dim LinkHref 
Dim a 

LinkHref = "//www.google.co.in/intl/en/about.html?fg=1" 

For Each a In ie.Document.GetElementsByTagName("A") 
    If LCase(a.GetAttribute("href")) = LCase(LinkHref) Then 
    a.Click 
    Exit For ''# to stop after the first hit 
    End If 
Next 

Answer 1

您可以用QTP编程描述实现目标（如果你不希望使用对象存储库出于某种原因）。此代码应该给你的你可以做什么的例子：

Dim oDesc ' create a Description object for objects of class Link 
Set oDesc = Description.Create 
oDesc("micclass").value = "Link" 

'Find all the Links in the browser using ChildObjects 
Set obj = Browser("title=Google").Page("title=Google").ChildObjects(oDesc) 

Dim i 
'obj.Count value has the number of links in the page 
For i = 0 to obj.Count - 1 ' indexed from zero, so use 0 to Count -1 
    'get the name of all the links in the page   
    If obj(i).GetROProperty("innerhtml")= LinkHref Then 
     obj(i).Click 'click the link if it matched the href you specfied 
     Exit For ' no need to carry on the loop if we found the right link 
    End If 
Next 

如果您只需要使用VBScript中，你可以做这样的：

Dim oShell : Set oShell = CreateObject("Shell.Application") 
Dim oWindow 
For Each oWindow In oShell.Windows 
    If InStr(oWindow.FullName, "iexplore") > 0 Then 
     If InStr(1, oWindow.Document.Title, "Google", vbTextCompare) > 0 Then 
      Set ieApp = oWindow 
      Exit For 
     End If 
    End If 
Next 

LinkHref = "//www.google.co.in/intl/en/about.html?fg=1" 

For Each linky In ieApp.Document.GetElementsbyTagName("a") 
    If LCase(linky.GetAttribute("href")) = LCase(LinkHref) Then 
     linky.Click 
     Exit For 
    End If 
Next 

这是非常上面给出的答案由Ansgar，但有一点额外的修复对象错误。只有浏览器窗口具有Document.Title，并且循环正在处理每个打开的窗口，因此当循环尝试一个非IE窗口时会出现错误。该版本通过仅检查Document.Title来确定该窗口是否首先被识别为IE实例。

Answer 2

不知道QTP，但VBScript没有Like运算符。

这是附加到一个IE窗口与普通VBScript中的特定标题通常的方式：

Set app = CreateObject("Shell.Application") 
For Each wnd In app.Windows 
    If wnd.Name = "Internet Explorer" Then 
    If InStr(1, wnd.Document.Title, "Google", vbTextCompare) > 0 Then 
     Set ie = wnd 
     Exit For 
    End If 
    End If 
Next