在Perl中如何查找给定日期的上一个星期一的日期？

Question

我正在寻找一个Perl脚本，它可以给我任何指定日期的最后一个星期一。

例如对于日期2011-06-11，脚本应该会返回2011-06-06

Answer 1

我假设如果给定的日期是星期一，你想要相同的日期（而不是前一个星期一）。下面是与DateTime做到这一点的一种方法：

use DateTime; 

my $date = DateTime->new(year => 2011, month => 6, day => 11); 
my $desired_dow = 1;   # Monday 
$date->subtract(days => ($date->day_of_week - $desired_dow) % 7); 
print "$date\n"; 

（事实上，周一的特殊情况下，% 7是没有必要的，因为$date->day_of_week - 1将始终为0 – 6，并认为国防部7是无糖。OP但随着% 7，它适用于任何所需日的一周，而不仅仅是星期一）

如果你确实想在上周一，你可以改变减法：

$date->subtract(days => ($date->day_of_week - $desired_dow) % 7 || 7); 

如果您需要解析在命令行中输入的日期，则可能需要查看DateTime::Format::Natural。

Answer 2

Zeller's congruence会给你星期几。从那里它应该很容易。

Answer 3

你也可以使用Time :: ParseDate，它理解“上周一”。

一个班轮维护Perl的声誉：

perl -MTime::ParseDate -M'POSIX qw(strftime)' -l -e'foreach (@ARGV) { my $now= parsedate($_); my $e= parsedate("last Monday", NOW => $now) ; print "$_ : ", strftime "%F", localtime($e)}' 2011-06-11 2011-06-12 2011-06-13 2011-06-14 

而一个健全的脚本：

#!/usr/bin/perl 

use strict; 
use warnings; 

use Time::ParseDate; # to parse dates 
use POSIX qw(strftime); # to format dates 

foreach my $date (@ARGV) 
    { my $date_epoch= parsedate($date) || die"'cannot parse date '$date'\n"; 
    my $monday= parsedate("last Monday", NOW => $date_epoch);     # last Monday before NOW 
    print "Monday before $date: ", strftime("%F", localtime($monday)), "\n"; # %F is YYYY-MM-DD 
    } 

有两点要注意：如果日期是星期一，那么你得到的以前星期一，这可能会或可能不是你想要的，改变现在只需设置到第二天（每天添加60 * 60 * 24，到$ date_epoch）。然后Time :: ParseDate非常自由，例如2011-23-38会很高兴解析（如2012-12-09）。

Answer 4

很简单的东西，使用标准的Perl库。

#!/usr/bin/perl 

use strict; 
use warnings; 
use 5.010; 

use Time::Local; 
use POSIX 'strftime'; 

my $date = shift || die "No date given\n"; 

my @date = split /-/, $date; 
$date[0] -= 1900; 
$date[1]--; 

die "Invalid date: $date\n" unless @date == 3; 

my $now = timelocal(0, 0, 12, reverse @date); 

while (strftime('%u', localtime $now) != 1) { 
    $now -= 24 * 60 * 60; 
} 

我将把它留作练习，让读者查阅所使用的各种模块和功能。

如果您使用DateTime，它可能会更简单。

Answer 5

本着Perl的精神，有很多方法可以做到这一点。

use Modern::Perl; 
use Date::Calc qw/Day_of_Week/; 
my $date = '2011/6/11'; 
my @fields = split /\//, $date; 
my @new_date = Add_Delta_Days(@fields , 1 - Day_of_Week(@fields)); 
say join "/", @new_date; 

Answer 6

你可以使用Date::Manip，其中有一个Date_GetPrev功能和理解 “星期一”

$ perl -MDate::Manip -le 'print UnixDate(Date_GetPrev(shift, "Monday", 0), "%Y-%m-%d")' 2011-06-11 
2011-06-06 

Answer 7

在本月底，$tstamp将有时间戳你想：

use strict; 
use warnings; 
use POSIX qw<mktime>; 

my $time = '2011-06-11'; 

my ($year, $month, $day) = split /-0?/, $time; 
my $tstamp = mktime(0, 0, 0, $day, $month - 1, $year - 1900); 
my $dow = (localtime $tstamp)[6]; 
$tstamp -= (($dow > 1 ? 0 : 7) + $dow - 1) * 24 * 60 * 60; 

这假定“上周一”是指最近一次发生在星期一之前的到指定日期。“因此，如果星期几是星期一（1），那么它会减去另外的7。

Answer 8

如果你是一个像我这样的奴隶，并且必须使用没有库的公司Perl，并且不允许你安装它们，老式方法：

my $datestring = ""; 
my $secondsEpoc = time(); #gives the seconds from system epoch 
my $secondsWantedDate; 
my $seconds2substract; 

$datestring = localtime($secondsEpoc); 
print "Today's date and time ".$datestring."\n"; 
my ($second,$minute,$hour,$d,$M,$y,$wd,$yd) = (localtime)[0,1,2,3,4,5,6,7]; 
#print "hour: ".$hour; 
#print "minute: ".$minute; 
#print "second: ".$second; 
#print "week day: ".$wd; #week day is 1=Monday .. 7=Sunday 

$seconds2substract = 24 * 60 * 60; # seconds in 24 hours 
$secondsWantedDate=$secondsEpoc-$seconds2substract; 
$datestring = localtime($secondsWantedDate); 
print "Yesterday at the same time ".$datestring."\n"; 


my $days2Substract = $wd-1; 
$seconds2substract = ($days2Substract * 24 * 60 * 60); 
$secondsWantedDate=$secondsEpoc-$seconds2substract; 
$datestring = localtime($secondsWantedDate); 
print "Past Monday same time ".$datestring."\n"; 

$seconds2substract = ($days2Substract * 24 * 60 * 60) + ($hour *60 *60) + ($minute * 60) + $second; 
$secondsWantedDate = $secondsEpoc-$seconds2substract; 
$datestring = localtime($secondsWantedDate); 
print "Past Monday at 00:00:00 ".$datestring."\n"; 

希望它可以帮助别人

Answer 9

有很多方法可以做到这一点在Perl下面是如何将其与Perl库进行Moment

#!/usr/bin/perl 

use strict; 
use warnings FATAL => 'all'; 
use feature 'say'; 

use Moment; 

sub get_monday_date { 
    my ($date) = @_; 

    my $moment = Moment->new(dt => "$date 00:00:00"); 

    my $weekday_number = $moment->get_weekday_number(first_day => 'monday'); 

    my $monday = $moment->minus(day => ($weekday_number - 1)); 

    return $monday->get_d(); 
} 

say get_monday_date('2011-06-11'); # 2011-06-06