正则表达式 - Sed

Question

我将如何替换四和五后面的逗号|但不是那些跟随一个和两个？

\"One,Two, Three\" Four, Five, Six 

sed s'/,/|/'g 

我将不胜感激一个答案，可以适用于任何逗号内的转义引号，而不仅仅是这个例子。

另一个例子是：

Mr ,Joe,Lish,,\"Acme, Inc.\",\"9599 Park Avenue, Suite 301\",Manhattan,NY,10022,\"\"\"6 A MAILING LIST MMBR GENERAL\"\"\" 

Answer 1

有前瞻和回顾后运营商正则表达式。例如，Javascript调用

bodyText = bodyText.replace（/ Aa（？= A）/ g，'AaB'）;

如果后面跟着另一个“A”，则会将“Aa”替换为“AaB”，而将“AaBA”替换为您。它不会与“AaB”相匹配，因为“Aa”之后没有其他“A”。这是一个向前看的电话。

我相信lookbehind的语法是？ < =。因此，如果这些操作符由您使用的软件包支持，那么您可以使用它们匹配“，”前面加“四”或“五”，只替换“，”。

Answer 2

我想出了这样一个：

echo '\"One,Two, Three\" Four, Five, Six' | sed 's/\(\("[^"]*"\)\?[^",]\+\),/\1 |/g' 

其中假定线就像使用sed

[ ["someting"] word, ]* ["someting"] word 

Answer 3

方式一：

内容的 script.sed

：

## Substitute '\"' with '\n'. 
s/\\\"/\n/g 

## If there is an odd number of '\"' or the string doesn't end with '\"' I 
## will append some at the end. There is no danger, but it will be used to 
## avoid an infinite loop. 
## 1.- Save content to 'hold space'. 
## 2.- Remove all characters except '\n'. 
## 3.- Remove one of them because next command will add another one. 
## 4.- Put content in 'pattern space' to begin working with it. 
## So, if in original string there were 3 '\"', now there will be 6. ¡Fine! 
h 
s/[^\n]//g 
s/\n// 
H 
g 

## Label 'a'. 
:a 

## Save content to 'hold space'. 
h 

## Remove from first '\n' until end of line. 
s/\(\n\).*$/\1/ 

## Substitute all commas with pipes. 
s/,/|/g 

## Delete first newline. 
s/\n// 

## Append content to print as final output to 'hold space'. 
H 

## Recover rest of line from 'hold space'. 
g 

## Remove content modified just before. 
s/[^\n]*// 

## Save content to 'hold space'. 
h 

## Get first content between '\n'. 
s/\(\n[^\n]*\n\).*$/\1/ 
s/\n\{2,\}// 

## Susbtitute '\n' with original '\"'. 
s/\n/\\"/g 

## Append content to print as final output to 'hold space'. 
H 

## Recover rest of line from 'hold space'. 
g 

## Remove content printed just before. 
s/\n[^\n]*\n// 

/^\n/ { 
    s/\n//g 
    p 
    b 
} 

ba 

内容infile：

\"One,Two, Three\" Four, Five, Six 
One \"Two\", Three, Four, Five 
One \"Two, Three, Four, Five\" 
One \"Two\" Three, Four \"Five, Six\" 

运行它想：

sed -nf script.sed infile 

结果如下：

\"One,Two, Three\" Four| Five| Six 
One \"Two\"| Three| Four| Five 
One \"Two, Three, Four, Five\" 
One \"Two\" Three| Four \"Five, Six\" 

Answer 4

这可能会为你工作：

sed 's/^/\n/;:a;s/\n\("[^"]*"\|[^,]\)/\1\n/;ta;s/\n,/|\n/;ta;s/.$//' file 

Expla国家：

• 预先在模式空间换行。 s/^/\n/
• 制作标签:a
• 将换行符移动到引号之间的字符串或不是逗号的字符之间。 s/\n\("[^"]*"\|[^,]\)/\1\n/
• 如果替换是标签的成功循环。 ta
• 用\n,代替|\n。s/\n,/|\n/
• 如果替换是标签的成功循环。 ta
• 如果不进行替换，则全部删除换行符。 s/.$//

编辑：

其实任何字符的独特字符或组合可以用来代替\n：

echo 'Mr ,Joe,Lish,,\"Acme, Inc.\",\"9599 Park Avenue, Suite 301\",Manhattan,NY,10022,\"\"\"6 A MAILING LIST MMBR GENERAL\"\"\"' | 
sed 's/^/@@@/;:a;s/@@@\("[^"]*"\|[^,]\)/\1@@@/;ta;s/@@@,/|@@@/;ta;s/@@@$//' 
Mr |Joe|Lish||\"Acme, Inc.\"|\"9599 Park Avenue, Suite 301\"|Manhattan|NY|10022|\"\"\"6 A MAILING LIST MMBR GENERAL\"\"\"