操作系统架构检测脚本

Question

我刚刚下载了7zip（x86和x64）的两个.msi安装程序。有没有人有一个简单的脚本，我可以用它来检测操作系统体系结构并启动相应的.msi文件？

Answer 1

大概原油和不是很......“安全” ...

只是检查的C:\Program Files (x86)其中存在只出现在64位系统上。

Answer 2

这可能帮助

strComputer = "." 
Set objWMIService = GetObject("winmgmts:" _ 
& "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2") 

Set colProcessors = objWMIService.ExecQuery _ 
    ("Select * From Win32_Processor") 

For Each objProcessor in colProcessors 
    If objProcessor.Architecture = 0 Then 
    Wscript.Echo "This is an x86 computer." 
    ElseIf objProcessor.Architecture = 1 Then 
    Wscript.Echo "This is a MIPS computer." 
    ElseIf objProcessor.Architecture = 2 Then 
    Wscript.Echo "This is an Alpha computer." 
    ElseIf objProcessor.Architecture = 3 Then 
    Wscript.Echo "This is a PowerPC computer." 
    ElseIf objProcessor.Architecture = 5 Then 
    Wscript.Echo "This is a ARM computer." 
    ElseIf objProcessor.Architecture = 6 Then 
    Wscript.Echo "This is an ia64 computer." 
    ElseIf objProcessor.Architecture = 9 Then 
    Wscript.Echo "This is an x64 computer." 
    Else 
    Wscript.Echo "The computer type could not be determined." 
    End If 
Next 

Answer 3

你说的很简单，但没有指定的语言......

批次（CMD）：

IF /I %PROCESSOR_ARCHITECTURE% EQU x86 (
    msiexec /qn /i 7zip_x86.msi 
) ELSE (
    msiexec /qn /i 7zip_x86.msi 
) 

的VBScript（.VBS）：

Set oShell = WScript.CreateObject("WScript.Shell") 
proc_arch = oShell.ExpandEnvironmentStrings("%PROCESSOR_ARCHITECTURE%") 

Answer 4

我发现一个很棒的vbscrip t，由Monimoy Sanyal撰写，发布在Microsoft Technet上。 如果32位系统在64位硬件上运行，它还会提供有关系统体系结构的信息。 https://gallery.technet.microsoft.com/scriptcenter/Determine-If-Your-System-969670e3

Option Explicit 
Dim ObjWMI, ColSettings, ObjProcessor 
Dim StrComputer, ObjNetwork 
Set ObjNetwork = WScript.CreateObject("WScript.Network") 
StrComputer = Trim(ObjNetwork.ComputerName) 
Set ObjNetwork = Nothing 
WScript.Echo VbCrLf & "Computer Name: " & StrComputer 
WScript.Echo vbNullString 
Set ObjWMI = GetObject("WINMGMTS:" & "{ImpersonationLevel=Impersonate,AuthenticationLevel=Pkt}!\\" & StrComputer & "\Root\CIMV2") 
Set ColSettings = ObjWMI.ExecQuery ("SELECT * FROM Win32_Processor") 
For Each ObjProcessor In ColSettings 
Select Case ObjProcessor.Architecture 
    Case 0 
     WScript.Echo "Processor Architecture Used by the Platform: x86" 
    Case 6 
     WScript.Echo "Processor Architecture Used by the Platform: Itanium-Based System" 
    Case 9 
     WScript.Echo "Processor Architecture Used by the Platform: x64" 
End Select 
Select Case ObjProcessor.ProcessorType 
    Case 1 
     WScript.Echo "Processor Type: Other. Not in the Known List"  
    Case 2 
     WScript.Echo "Processor Type: Unknown Type" 
    Case 3 
     WScript.Echo "Processor Type: Central Processor (CPU)" 
    Case 4 
     WScript.Echo "Processor Type: Math Processor" 
    Case 5 
     WScript.Echo "Processor Type: DSP Processor" 
    Case 6 
     WScript.Echo "Processor Type: Video Processor" 
End Select 
WScript.Echo "Processor: " & ObjProcessor.DataWidth & "-Bit" 
WScript.Echo "Operating System: " & ObjProcessor.AddressWidth & "-Bit" 
WScript.Echo vbNullString  
If ObjProcessor.Architecture = 0 AND ObjProcessor.AddressWidth = 32 Then 
    WScript.Echo "This Machine has 32 Bit Processor and Running 32 Bit OS" 
End If 
If (ObjProcessor.Architecture = 6 OR ObjProcessor.Architecture = 9) AND ObjProcessor.DataWidth = 64 AND ObjProcessor.AddressWidth = 32 Then 
    WScript.Echo "This Machine has 64-Bit Processor and Running 32-Bit OS" 
End If 
If (ObjProcessor.Architecture = 6 OR ObjProcessor.Architecture = 9) AND ObjProcessor.DataWidth = 64 AND ObjProcessor.AddressWidth = 64 Then 
    WScript.Echo "This Machine has 64-Bit Processor and Running 64-Bit OS" 
End If 
Next 
Set ObjProcessor = Nothing: Set ColSettings = Nothing: Set ObjWMI = Nothing: StrComputer = vbNullstring