如何在XSLT中循环？

Question

我有以下XML结构：

<Article> 
     <id>1</id> 
     <line>L11</line> 
     <line>L12</line> 
     <line>L13</line> 
    </Article> 
    <Article> 
     <id>2</id> 
     <line>L21</line> 
     <line>L22</line> 
     <line>L23</line> 
    </Article> 

我想使用XSLT在一次迭代仅一文在所有的线，所以我可以实现以下结构：（每篇文章转化为顺序，其线条转换为线结构在新的结构）

 <orders> 
      <order> 
       <id>1</id> 
       <order_line>L11</order_line> 
       <order_line>L12</order_line> 
       <order_line>L13</order_line> 
      </order> 
      <order> 
       <id>2</id> 
       <order_line>L21</order_line> 
       <order_line>L22</order_line> 
       <order_line>L23</order_line> 
      </order> 
     </orders> 

Answer 1

使用XSLT，尝试用手去思考的任务为一组的模式，或者你有相匹配的规则，并且遇到这样的格局，每次将要采取的行动。通常可以让运行时间担心循环等，以发现模式。

在您的具体情况下，您已经描述了两种需要特殊逻辑的模式。每次有元素Article时，您都希望应用规则将其名称更改为order。 每次遇到line作为Article的子项时，请将其替换为order_line。对于任何其他的模式，你只是想，因为他们是在原始文档中的内容复制：

<!-- Match element Article, and whenever it's encountered, insert an 'order' element, and copy the contents of Article --> 
<xsl:template match="Article"> 
    <order> <xsl:apply-templates/> </order> 
</xsl:template> 

<!-- Match element 'line', and whenever it's encountered, insert an 'order_line' element, and copy the contents --> 
<xsl:template match="Article/line"> 
    <order_line> <xsl:apply-templates/> </order_line> 
</xsl:template> 

<!-- Match any other element we haven't specified explicity, and copy it verbatim --> 
<xsl:template match="node()"> 
    <xsl:copy> 
    <xsl:apply-templates/> 
    </xsl:copy> 
</xsl:template> 

Answer 2

这只是我的头顶，但我认为你可以这样来做：

<orders> 
<xsl:for-each select="//Article"> 
    <order> 
    <id><xsl:value-of select="./id"/></id> 
    <xsl:for-each select="./line"> 
    <order_line><xsl:value-of select="child::text()" /></order_line> 
    </xsl:for-each> 
    </order> 
</xsl:for-each> 
</orders> 

无论如何，它应该足以让你开始。尽管XSLT中只有for-each循环，但没有for循环与计数器。

Answer 3

您的源XML文件格式不正确。为了清楚起见，我的回应假定你已经将它包装在一个元素中。这是一个非常简单的XML转换，所以我已经包含了一些解释每行代码在做什么的注释。

<!-- change the template match xpath to whatever the root xpath is in your document --> 
<xsl:template match="root"> 
    <orders> 
     <!-- loop over each Article --> 
     <xsl:for-each select="Article"> 
      <order> 
       <!-- pass id through --> 
       <xsl:copy-of select="id"/> 
       <!-- loop over each line --> 
       <xsl:for-each select="line"> 
        <!-- create an <order_line> node --> 
        <order_line> 
         <!-- get the value of the current <line> --> 
         <xsl:value-of select="."/> 
        </order_line> 
       </xsl:for-each> 
      </order> 
     </xsl:for-each> 
    </orders> 
</xsl:template> 

Answer 4

这是一个简单的转换：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:template match="/*"> 
     <orders> 
      <xsl:apply-templates/> 
     </orders> 
    </xsl:template> 
    <xsl:template match="Article"> 
     <order> 
      <xsl:apply-templates/> 
     </order> 
    </xsl:template> 
    <xsl:template match="line"> 
     <order_line> 
      <xsl:apply-templates/> 
     </order_line> 
    </xsl:template> 
    <xsl:template match="id"> 
     <xsl:copy> 
      <xsl:apply-templates/> 
     </xsl:copy> 
    </xsl:template> 
</xsl:stylesheet> 

编辑：一般的根元素规则。

Answer 5

在XSLT中执行“循环”的正确方法是让XSLT处理器为您遍历文档树。其他任何事情都在与XSLT的本质作斗争。

这里有一个（近）的完整解决方案：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:template match="/"> 
     <orders><xsl:apply-templates/></orders> 
    </xsl:template> 
    <xsl:template match="Article"> 
     <order> 
      <id><xsl:value-of select="id"/></id> 
      <xsl:apply-templates select="line"/> 
     </order> 
    </xsl:template> 
    <xsl:template match="Article/line"> 
     <order_line><xsl:value-of select="."/></order_line> 
    </xsl:template> 
</xsl:stylesheet> 

Answer 6

试试这个，但我不是一个XSLT专家:)

<?xml version="1.0" encoding="utf-8"?> 

<xsl:template match="/" name="A"> 
    <orders> 
     <xsl:for-each select="Articles/Article"> 
      <order> 
       <id> 
        <xsl:value-of select="id" /> 
       </id> 
       <xsl:for-each select="line"> 
        <order_line> 
         <xsl:value-of select="node()"></xsl:value-of> 
        </order_line> 
       </xsl:for-each> 
      </order> 
     </xsl:for-each> 
    </orders> 
</xsl:template> 

Answer 7

这是完整的XSLT 1。0变换：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
    <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="/*"> 
    <orders> 
    <xsl:apply-templates/> 
    </orders> 
</xsl:template> 

<xsl:template match="Article"> 
    <order> 
    <xsl:apply-templates/> 
    </order> 
</xsl:template> 

<xsl:template match="line"> 
    <order_line> 
    <xsl:apply-templates/> 
    </order_line> 
</xsl:template> 
</xsl:stylesheet> 

当施加上所提供的XML文档（包裹成一个单一的顶部元件，使其充分形成的）：

<t> 
    <Article> 
     <id>1</id> 
     <line>L11</line> 
     <line>L12</line> 
     <line>L13</line> 
    </Article> 
    <Article> 
     <id>2</id> 
     <line>L21</line> 
     <line>L22</line> 
     <line>L23</line> 
    </Article> 
</t> 

产生想要的，正确的结果：

<orders> 
    <order> 
     <id>1</id> 
     <order_line>L11</order_line> 
     <order_line>L12</order_line> 
     <order_line>L13</order_line> 
    </order> 
    <order> 
     <id>2</id> 
     <order_line>L21</order_line> 
     <order_line>L22</order_line> 
     <order_line>L23</order_line> 
    </order> 
</orders> 

说明：

1. 身份规则将“按原样”复制每个节点。 orders，order和order_line：

2. 身份规则由三个模板，其中的每一个匹配的特定种类的元素（顶部元件，Article和line）和简单地重命名元件，以分别覆盖。