Excel VBA将数据写入类模块中的字典

Question

我想将数据保存在类模块中声明的字典中。我在课堂模块中使用过一本字典，因为在开始时组的数量和关联的数据点是未知的。下面的代码会编译，但模块和类模块中的dRATIO.exists语句都返回false（但是，在第一次传递类模块中的调试语句时会给出正确的值，其后的错误），然后Function GetRATIO会返回999.任何建议？

'CODE IN A CLASS MODULE CALLED clsIVDATA 
Option Explicit 

Public dRATIO 
Public dIV 
' 

Sub Init(RATIO As Variant, IV As Variant, KEY As String) 

'Dim I As Long 
Dim VAL As String 
Dim RowKeys 
Dim COLKEYS 

Set dRATIO = CreateObject("Scripting.Dictionary") 
Set dIV = CreateObject("Scripting.Dictionary") 

dRATIO.ADD ITEM:=RATIO, KEY:=KEY 
dIV.ADD ITEM:=RATIO, KEY:=KEY 

Debug.Print dRATIO.Exists("1") 
Debug.Print dRATIO.ITEM("1") 

End Sub 


Function GetRATIO(KEY As String) 
    If dRATIO.Exists(KEY) Then 
     GetRATIO = dRATIO(KEY) 
    Else 
     GetRATIO = 999 'or raise an error... 
    End If 
End Function 

Function NO_VALUES() 

NO_VALUES = dRATIO.COUNT 

End Function 

Function GetIV(KEY As String) 
    If dIV.Exists(KEY) Then 
     GetIV = dIV(KEY) 
    Else 
     GetIV = 999 'or raise an error... 
    End If 
End Function 

'===================================================== 
'CODE IN A NORMAL MODULE 
Sub tstclass() 
Dim RATIO() As Variant 
Dim IV() As Variant 
Dim I As Integer 

Dim dctSKEW As Object 
Set dctSKEW = CreateObject("Scripting.Dictionary") 
dctSKEW.ADD "APZ4", New clsIVDATA 

RATIO = Array(0.879, 0.843, 0.802, 0.756, 0.658) 
IV = Array(0.165, 0.156, 0.145, 0.136, 0.125) 

For I = 1 To 5 
    KEY = CStr(I) 
    dctSKEW("APZ4").Init RATIO(I), IV(I), KEY 
Next I 

Debug.Print dctSKEW("APZ4").GetRATIO("1") 
Debug.Print dctSKEW("APZ4").GetRATIO("2") 
Debug.Print dctSKEW("APZ4").NO_VALUES 

End Sub 

Answer 1

你的主要问题是你混合了正开始与加载项将它（每次通话时间clsIVDATA.Init要创建一个新的空字典）的Dictioary对象。

此外，使用Array(...)生成的数组基于0，因此您的For循环将会出错并产生意外结果。

这里是你的代码重构为解决这些问题和其他一些次要问题

类代码

Option Explicit 

'CODE IN A CLASS MODULE CALLED clsIVDATA 

Private dRATIO As Object 
Private dIV As Object 
' 

Private Sub Class_Initialize() 
    Set dRATIO = CreateObject("Scripting.Dictionary") 
    Set dIV = CreateObject("Scripting.Dictionary") 
End Sub 

Sub Init(RATIO As Variant, IV As Variant, KEY As String) 
    dRATIO.Add Item:=RATIO, KEY:=KEY 
    dIV.Add Item:=RATIO, KEY:=KEY 
End Sub 

Function GetRATIO(KEY As String) 
    If dRATIO.Exists(KEY) Then 
     GetRATIO = dRATIO(KEY) 
    Else 
     GetRATIO = 999 'or raise an error... 
    End If 
End Function 

Function NO_VALUES() 
    NO_VALUES = dRATIO.Count 
End Function 

Function GetIV(KEY As String) 
    If dIV.Exists(KEY) Then 
     GetIV = dIV(KEY) 
    Else 
     GetIV = 999 'or raise an error... 
    End If 
End Function 

模块代码

Option Explicit 

'===================================================== 
'CODE IN A NORMAL MODULE 
Sub tstclass() 
    Dim RATIO() As Variant, KEY As String 
    Dim IV() As Variant 
    Dim I As Long 
    Dim c As clsIVDATA 

    Dim dctSKEW As Object 
    Set dctSKEW = CreateObject("Scripting.Dictionary") 
    dctSKEW.Add "APZ4", New clsIVDATA 

    Set c = dctSKEW.Item("APZ4") 
    RATIO = Array(0.879, 0.843, 0.802, 0.756, 0.658) 
    IV = Array(0.165, 0.156, 0.145, 0.136, 0.125) 

    For I = 0 To 4 
     KEY = CStr(I + 1) 
     c.Init RATIO(I), IV(I), KEY 
    Next I 

    Debug.Print dctSKEW("APZ4").GetRATIO("1") 
    Debug.Print dctSKEW("APZ4").GetRATIO("2") 
    Debug.Print dctSKEW("APZ4").NO_VALUES 

End Sub