获取Windows批处理文件根据通配符匹配的内容重命名文本文件

Question

我有以下批处理文件，它通过将文件内容中的下划线和字符附加到文件名来重命名文本文件。

内容是从位置在文件中的第一行5个字符56

我能得到这个在我的例子单个文件（1.spl）工作，但我不能工作了如何让它运行文件夹中的所有* .spl文件。

@ECHO OFF 
SETLOCAL EnableDelayedExpansion 

for /F "delims=" %%i in (1.spl) do ( 
    set Z=%%i 
    goto BREAK1 
) 
:BREAK1 

SET Z=%Z:~56,5% 
RENAME 1.spl 1_%Z%.spl 

Answer 1

你可以使用另一个FOR循环这就要求每一个* .spl文件子程序重命名文件。

@echo off 
setlocal EnableExtensions DisableDelayedExpansion 
for /F "delims=" %%# in ('dir *.spl /A-D /B 2^>nul') do call :RenameFile "%%#" 
endlocal 
goto :EOF 

:RenameFile 
for /F "usebackq delims=" %%I in (%1) do set "FirstLine=%%I" & goto GetNamePart 
:GetNamePart 
set "NamePart=%FirstLine:~56,5%" 
if not exist "%~n1_%NamePart%%~x1" ren %1 "%~n1_%NamePart%%~x1" 
goto :EOF 

的FOR主代码环 - 第三行 - 使用命令DIR开始重命名操作之前获得的* .spl文件的文件列表。在此仅使用for %%# in (*.spl) do ...作为当前目录中的文件被重命名是不可取的，这意味着目录条目改变，而FOR循环正在运行。强烈建议首先获得 * .spl文件的完整列表，使用DIR和然后独立处理目录中的文件重命名。

主对于调用子程序RenameFile来处理列表中的每个文件。

如果已存在具有相同名称的现有文件，则不会重命名文件。这是不太可能的，但应该首先检查。

请注意，如果批处理文件在目录上执行多次，批处理代码不会阻止将多个第一行的下划线和五个字符附加到文件名。需要额外的IF条件以避免多次重命名文件。

为了解所使用的命令及其工作方式，请打开命令提示符窗口，在其中执行以下命令，并仔细阅读为每个命令显示的所有帮助页面。

• call /?
• echo /?
• endlocal /?
• for /?
• goto /?
• if /?
• ren /?
• set /?
• setlocal /?

作为在子程序环上使用的操作者&使得有可能在单个命令行上运行多个命令，请参见Single line with multiple commands using Windows batch file的详细信息。