XSLT：在XSLT中创建映射

Question

我想在xsl中有一个键值映射，因此定义了一个具有xml片段的变量，但后来当我尝试访问变量中的xml节点时，出现一个类型错误的xpath xpression无法解析。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:template match="/"> 
     <xsl:variable name="map"> 
      <map> 
       <entry key="key-1">value1</entry> 
       <entry key="key-2">value2</entry> 
       <entry key="key-3">value3</entry> 
      </map> 
     </xsl:variable> 
     <output> 
      <xsl:value-of select="$map/entry[@key='key-1']"/> 
     </output> 
    </xsl:template> 
</xsl:stylesheet> 

Answer 1

XSLT 2.0

使用XSLT 2.0，下面的解决方案的工作原理：

<xsl:variable name="map"> 
    <entry key="key-1">value1</entry> 
    <entry key="key-2">value2</entry> 
    <entry key="key-3">value3</entry> 
    </xsl:variable> 

    <xsl:template match="/"> 
    <output> 
     <xsl:value-of select="$map/entry[@key='key-1']"/> 
    </output> 
    </xsl:template> 

XSLT 1.0

不能在XSLT 1.0在XPath表达式使用结果树片断，但fn:document()可以检索地图值。对similar question的回答将在此处起作用。

<xsl:value-of select="document('')//xsl:variable[@name='map']/map/entry[@key='key-1']"/> 

如在描述的XSLT 1.0 specification：

document('')指 样式表中的根节点;样式表的表示形式 与 的表示形式完全相同，就好像包含样式表的XML 文档是 的初始源文档。

但是，您不需要为此使用xsl:variable。你可以指定地图节点直属xsl:stylesheet，但你必须记住，一个顶级元素必须有一个非空的命名空间URI：

<xsl:stylesheet 
    version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:my="some.uri" exclude-result-prefixes="my"> 

    <my:map> 
    <entry key="key-1">value1</entry> 
    <entry key="key-2">value2</entry> 
    <entry key="key-3">value3</entry> 
    </my:map> 

    <xsl:template match="/"> 
    <output> 
     <xsl:value-of select="document('')/*/my:map/entry[@key='key-1']"/> 
    </output> 
    </xsl:template> 
</xsl:stylesheet> 

Answer 2

您可以按工作围绕XSLT 1.0缺少使用变量的内容作为支撑一个节点集。您将不得不依赖分析器制造商添加的扩展。例如，微软已经提供了一个函数来解决此问题：节点集（）

你XSL看起来就像这样：

<xsl:stylesheet version="1.0" 
       xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
       xmlns:msxsl="urn:schemas-microsoft-com:xslt"> 
    <xsl:template match="/"> 
     <xsl:variable name="map"> 
      <map> 
       <entry key="key-1">value1</entry> 
       <entry key="key-2">value2</entry> 
       <entry key="key-3">value3</entry> 
      </map> 
     </xsl:variable> 
     <output> 
      <xsl:value-of select="msxsl:node-set($map)/map/entry[@key='key-1']"/> 
     </output> 
    </xsl:template> 
</xsl:stylesheet> 

声明命名空间和msxsl前缀在这里。这只适用于基于Microsoft解析器的应用程序（例如：Internet Explorer使用它以及.NET）。其他解析器可能有也可能没有这样的扩展（例如Saxxon，但它的命名有所不同）。但是，它取决于XSLT 2.0，因为这在XSLT 1.0中可以正常工作，而且Microsoft尚未在其XML库中支持XSLT 2.0（除非他们最近添加了XSLT 2.0）。

根据您使用的解析器，上述可能适合您，否则Per T的答案更适合您。

Answer 3

在XSLT 3.0工作草案中，提出了一种新的XPath项目（地图），请参阅maps in XSLT 3.0 WD Spec。

所以，如果您的XSLT处理器支持3.0和地图（如撒克逊9.4），你可以使用下面的代码：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:xs="http://www.w3.org/2001/XMLSchema" 
    exclude-result-prefixes="xs" 
    version="3.0"> 
    <xsl:output indent="yes"/> 

    <xsl:template match="/"> 
    <xsl:variable name="map" select=" 
     map { 
     'key-1' := 'value1', 
     'key-2' := 'value2', 
     'key-3' := 'value3' }">  
    </xsl:variable> 
    <output> 
     <xsl:value-of select=" 
     $map('key-1') || ', ' || $map('key-2') || ', ' || $map('key-3')"/> 
    </output> 
    </xsl:template> 
</xsl:stylesheet>