dbpedia SPARQL查询获得给定城市的特定值

Question

我确定我想要做的事很容易，但我似乎无法得到正确的查询。我在数据集中记录具有诸如城市名称的值的记录，例如'纽约'和相应的国家代码，例如'美国'。我也可以访问完整的国家名称和国家ISO代码。

我想获得人口和抽象价值的这些城市离DBpedia中，通过使用where子句，如：

Get population where name = "New York" and isoCountryCode = "US" 

我搜索了这个求助无果。

到目前为止，我已经好心的@rohk与此查询，它不完全为所有地点的工作帮助：纽约

SELECT DISTINCT ?city ?abstract ?pop 
WHERE { 
    ?city rdf:type schema:City ; 
    rdfs:label ?label ; 
    dbpedia-owl:abstract ?abstract ; 
    dbpedia-owl:country ?country ; 
    dbpedia-owl:populationTotal ?pop . 
    ?country dbpprop:countryCode "USA"@en . 
    FILTER (lang(?abstract) = 'en' and regex(?label, "New York City")) 
} 

上述工作，但是当我将其更改为：

SELECT DISTINCT ?city ?abstract ?pop 
WHERE { 
    ?city rdf:type schema:City ; 
     rdfs:label ?label ; 
     dbpedia-owl:abstract ?abstract ; 
     dbpedia-owl:country ?country ; 
     dbpedia-owl:populationTotal ?pop . 
    ?country dbpprop:countryCode "THA"@en . 
    FILTER (lang(?abstract) = 'en' and regex(?label, "Bangkok")) 
} 

它不返回泰国曼谷的结果。

我只是不能得到正确的SPARQL查询，我敢肯定我是愚蠢的与我的查询。如果任何一位大师能够提供帮助，我会很感激。谢谢！

Answer 1

此查询工作

SELECT DISTINCT * 
WHERE { 
    ?city rdf:type schema:City ; 
     rdfs:label ?label ; 
     dbpedia-owl:abstract ?abstract ; 
     dbpedia-owl:country ?country ; 
     dbpprop:website ?website ; 
     dbpedia-owl:populationTotal ?pop . 
    ?country dbpprop:countryCode "USA"@en . 
    FILTER (lang(?abstract) = 'en' and regex(?label, "New York City")) 
} 

编辑：曼谷，有2个问题：泰国

• 没有一个国家代码：你可以使用rdfs:label "Thailand"@en代替。
• 曼谷的rdf:type不是schema:City但dbpedia-owl:Settlement

这里是曼谷

SELECT DISTINCT * 
WHERE { 
    ?city rdf:type dbpedia-owl:Settlement ; 
     rdfs:label "Bangkok"@en ; 
     dbpedia-owl:abstract ?abstract ; 
     dbpedia-owl:populationTotal ?pop ; 
     dbpedia-owl:country ?country ; 
     dbpprop:website ?website . 
    ?country rdfs:label "Thailand"@en . 
    FILTER (lang(?abstract) = 'en') 
} 

Answer 2

工作查询我想你想是这样的：

SELECT * WHERE { 
    ?x rdfs:label "New York City"@en. 
    ?x dbpedia-owl:populationTotal ?pop. 
    ?x dbpedia-owl:abstract ?abstract. 
} 

，仅保留英文摘要，加一个FILTER：

SELECT * WHERE { 
    ?x rdfs:label "New York City"@en. 
    ?x dbpedia-owl:populationTotal ?pop. 
    ?x dbpedia-owl:abstract ?abstract. 
    FILTER (LANG(?abstract) = 'en') 
} 

“纽约州”是州，它没有附上populationTotal附图。 “纽约市”就是这座城市。