如何使用xpath替换xml中的第一个节点属性值

Question

在下面的XML中，需要使用XPath替换名称空间。

<application xmlns="http://ns.adobe.com/air/application/4.0"> 
    <child id="1"></child> 
    <child id="2"></child> 
</application> 

我试着用

/application/@xmlns 

和

/*[local-name()='application']/@[local-name()='xmlns'] 

双方未能给予的愿望输出。为了替换文本，我使用了xmltask替换。

<xmltask source="${temp.file1}" dest="${temp.file1}"> 
    <replace path="/application/@xmlns" withText="http://ns.adobe.com/air/application/16.0" /> 
</xmltask> 

Answer 1

问题是xmlns不是属性。您无法使用XPath进行选择。

命名空间是节点名称的一部分在XML：<foo xmlns="urn:foo-namespace" />和<foo xmlns="urn:bar-namespace" />是不两次与相同的名称和不同的属性节点，它们是具有不同名称的两个节点和没有属性。

如果要更改命名空间，则必须构造一个全新的节点。

XSLT是更好的适合于这项任务：

<!-- update-air-ns.xsl --> 
<xsl:transform 
    version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:air4="http://ns.adobe.com/air/application/4.0" 
    xmlns="http://ns.adobe.com/air/application/16.0" 
> 
    <xsl:output method="xml" encoding="UTF-8" indent="yes" /> 

    <xsl:template match="@*|node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*|node()"/> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="air4:*"> 
     <xsl:element name="{local-name()}"> 
      <xsl:apply-templates select="@*|node()"/> 
     </xsl:element> 
    </xsl:template> 
</xsl:transform> 

这XSLT转换做了两两件事：

• 第一模板（身份模板）递归复制节点，除非有更好的匹配给定节点的模板
• 第二个模板匹配air4名称空间中的元素，并构造具有相同本地名称但名称空间不同的新元素。发生这种情况是因为XSLT中的默认名称空间声明。所有新构造的元素都使用http://ns.adobe.com/air/application/16.0命名空间。

应用到您输入XML，结果是

<application xmlns="http://ns.adobe.com/air/application/16.0"> 
    <child id="1"/> 
    <child id="2"/> 
</application> 

您可以使用Ant的XSLT任务：

<xslt in="${temp.file1}" out="${temp.file1}" style="update-air-ns.xsl" />