如何在Perl中获得外部命令的输出？

Question

我想输出写入使用Perl创建的文件的Windows命令行程序（例如，powercfg -l），然后在for循环中逐行读取文件并将其分配给字符串。

Answer 1

my $output = qx(powercfg -l); 

## You've got your output loaded into the $output variable. 
## Still want to write it to a file? 
open my $OUTPUT, '>', 'output.txt' or die "Couldn't open output.txt: $!\n"; 
print $OUTPUT $output; 
close $OUTPUT 

## Now you can loop through each line and 
## parse the $line variable to extract the info you are looking for. 
foreach my $line (split /[\r\n]+/, $output) { 
    ## Regular expression magic to grab what you want 
} 

Answer 2

system 'powercfg', '-l'; 

是推荐的方法。如果你不介意产生子壳，

system "powercfg -l"; 

也可以。如果你想在一个字符串的结果：

my $str = `powercfg -l`; 

Answer 3

由于OP运行powercfg，他/她可能正在捕捉外部脚本的输出中，那么他/她可能会找不到这个答案非常有用。这篇文章主要是为通过搜索找到答案的其他人撰写的。

此答案描述了几种启动将在后台运行的命令的方法，而不会阻止脚本的进一步执行。

看看perlport entry for system。你可以使用system(1, 'command line to run');产生一个子进程并继续你的脚本。

这真的很方便，但有一个严重的警告是不是记录。如果在脚本的一次执行中启动更多64个进程，则尝试运行其他程序将失败。

我已经验证这是Windows XP和ActivePerl 5.6和5.8的情况。我还没有用Vista或Stawberry Perl或5.10的任何版本进行测试。

这里有一个衬垫，你可以用它来测试你的Perl对于这个问题：

C:\>perl -e "for (1..100) { print qq'\n $_\n-------\n'; system(1, 'echo worked'), sleep 1 } 

如果你的系统中存在的问题，你会开始很多程序，你可以使用Win32::Process模块管理你的程序启动。

下面是一个使用Win32::Process的例子：

use strict; 
use warnings; 

use Win32::Process; 

if(my $pid = start_foo_bar_baz()) { 
    print "Started with $pid"; 
} 
:w 

sub start_foo_bar_baz { 

    my $process_object; # Call to Create will populate this value. 
    my $command = 'C:/foo/bar/baz.exe'; # FULL PATH to executable. 
    my $command_line = join ' ', 
      'baz', # Name of executable as would appear on command line 
      'arg1', # other args 
      'arg2'; 

    # iflags - controls whether process will inherit parent handles, console, etc. 
    my $inherit_flags = DETACHED_PROCESS; 

    # cflags - Process creation flags. 
    my $creation_flags = NORMAL_PRIORITY_CLASS; 

    # Path of process working directory 
    my $working_directory = 'C:/Foo/Bar'; 

    my $ok = Win32::Process::Create(
     $process_object, 
     $command, 
     $command_line, 
     $inherit_flags, 
     $creation_flags, 
     $working_directory, 
    ); 

    my $pid; 
    if ($ok) { 
     $pid = $wpc->GetProcessID; 
    } 
    else { 
     warn "Unable to create process: " 
      . Win32::FormatMessage(Win32::GetLastError()) 
     ; 
     return; 
    } 

    return $pid; 
} 

Answer 4

尝试使用>运算符输出转发到一个文件，如：

powercfg -l > output.txt 

，然后打开output.txt中，并对其进行处理。

Answer 5

没有必要先保存命令的输出文件：

my $output = `powercfg -l`; 

见qx//在Quote-Like Operators。

但是，如果你想先保存在一个文件输出，那么你可以使用：

my $output_file = 'output.txt'; 

system "powercfg -l > $output_file"; 

open my $fh, '<', $output_file 
    or die "Cannot open '$output_file' for reading: $!"; 

while (my $line = <$fh>) { 
    # process lines 
} 

close $fh; 

见perldoc -f system。

Answer 6

要扩大思南的出色答卷，并更明确地回答你的问题：

注：反引号``告诉Perl来执行命令和检索其输出：

#!/usr/bin/perl -w 
use strict; 


my @output = `powercfg -l`; 
chomp(@output); # removes newlines 

my $linecounter = 0;  
my $combined_line; 

foreach my $line(@output){ 
    print $linecounter++.")"; 
    print $line."\n"; #prints line by line 

    $combined_line .= $line; # build a single string with all lines 
    # The line above is the same as writing: 
    # $combined_line = $combined_line.$line; 
} 

print "\n"; 
print "This is all on one line:\n"; 
print ">".$combined_line."<"; 

你的输出（在我的系统上）应该是：

0) 
1)Existing Power Schemes (* Active) 
2)----------------------------------- 
3)Power Scheme GUID: 381b4222-f694-41f0-9685-ff5bb260df2e (Balanced) * 
4)Power Scheme GUID: 8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c (High performance) 
5)Power Scheme GUID: a1841308-3541-4fab-bc81-f71556f20b4a (Power saver) 

This is all on one line: 
>Existing Power Schemes (* Active)-----------------------------------Power Scheme GUID: 381b4222-f694-41f0-9685-ff5bb260df2e (Balanced) *Power Scheme GUID: 8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c (High performance)Power Scheme GUID: a1841308-3541-4fab-bc81-f71556f20b4a (Power saver)< 

Perl让它变得简单！

Answer 7

你已经有了一些很好的答案。另外，如果您只想处理命令的输出，而不需要直接将该输出发送到文件，则可以在命令和Perl脚本之间建立管道。

use strict; 
use warnings; 

open(my $fh, '-|', 'powercfg -l') or die $!; 
while (my $line = <$fh>) { 
    # Do stuff with each $line. 
}